Directory of image this file is from
This file as a plain text file

[SPECT3
[REVISED TO GIVE
[3 SMALLER PLOTS
[INCLUDES
[CONTROL,
[LIST READER,
[SPECTRUM,
[PLOT CONTROL
[PLOTTER
$20
RDCi
7Z+2002
[LOAD Q2
RDCi
7Z+1003
[LOAD COMPILER
RDCi
7Z+4004
RDCi
7Z+5005
RDCi
7Z+6006
RDC
7Z+7007
[LOAD COSINES
JMP 400
[TO COMPILER
#2N RDC
7Z+1001
[LOAD PLOTTER
LDAi
3333
STC 5Q
STC 5G
JMP 4P
3000
0
-3
JMP 4P
-2020
0
-3
SETi12
2A-1
#2K LDAi12
APOi
JMP p+12
SAEi
7777
JMP p+2
HLT
COM
BSEi
3000
STC 2J
JMP p+10
BSEi
3000
STA
2J
BCLi
7000
ADAi12
ADD 2P
STC 10
RDCu
#2J 3000
JMP 2M-3
[GO TO SPECT
[AND PLOT,
[THEN RETURN
LDAi
1
ADM
2J
XSKi10
JMP 2J-1
JMP 2K
#2P -1
[SPECTRUM
LDA
1777
STAi
#2M 0
SETi1
1377
SETi2
1377
SETi3
7777
[SCALE AND
[TRUNCATE AUTO-
[CORRELOGRAM
#2B LDAi1
ROL 3
MULi3
STAi2
XSKi3
XSKi1
JMP 2B
CLR
STAi2
XSK 2
JMP p-2
SETi4
1
SETi5
1577
[SUM OF CROSS
[PRODUCTS OF
[COSINE AND
[AUTOCORREL.
#2C CLR
STC 2H
STC 2L
SETi1
1377
SETi2
-200
SETi3
6000
#2D LDAi1
MUL 3
STAi
#2E 0
SCR 13
STAi
#2F 0
CLR
ADD 2E
LAMi
#2L 0
STC 0
ADD 2F
LAMi
#2H 0
STC 0
LAM
2L
STC 0
LAM
2H
LDA
3
BCLi
6000
ADD 4
BSEi
6000
STC 3
XSKi2
JMP 2D
[DOUBLE-PREC.
[SCR 7
SETi2
-7
#2G LDA
2H
SCRi1
STC 2H
ADD 2L
RORi1
STC 2L
XSKi2
JMP 2G
ADD 2L
STAi5
XSKi4
XSK 5
JMP 2C
SETi1
1600
SETi2
1377
[INTERPOLATE
[AND REMOVE NEG
[VALUES
#2I LDA 1
APO
CLR
STAi2
SCR 1
STAi
0
LDAi1
SCR 1
ADD p-3
APO
CLR
STAi2
XSK 1
JMP 2I
LDA 1
APO
CLR
STAi2
[PLOT CONTROL
CLR
STC 5E
ADD 5D
STC 5L+1
ADD 5K
STA
5L
STC 5M
JMP 4N
SETi3
1400
#5J LDA 3
STA 
5F
COM
ADD 5G
APOi
JMP p+3
LDA 3
STC 5G
LDA
3
ADAi
-1400
STC 5H
JMP 4P
#5H 0
#5F 0
1
XSKi3
JMP 5J
JMP 4P
#5K 376
0
3
JMP 4N
JMP 4P
#5L 376
-40
1
JMP 4P
#5M 376
0
1
LDAi
-20
ADM
5L
STA
5M
STC 5N
LDAi
#5E 0000
COM
STA
5E
APO
JMP p+4
LDAi
#5D -10
JMP p+3
LDAi
#5C -4
STC 5L+1
ADD p+4
APO
JMP p+6
JMP 4P
#5N 356
0
1
JMP 5L-1
JMP 4P
0
0
1
JMP 4P
0
-40
3
LDA
2M
ROL 3
ROL 3
STAi
000
BCLi
7770
JMP 4U
LDA
p-5
SROi
3333
JMP p-12
LDAi
10
JMP 4U
LDA
2M
ROL 3
BCLi
7770
JMP 4U
JMP 4P
540
0
-3
SROi
#5Q 3333
JMP 2J+2
LDAi
100
ADM
5G
JMP 4P
-2020
#5G 0000
-3
CLR
STC 5G
JMP 2J+2
[END PLOT CONTR
[SPECT3
[BLOCK 1B
[PLOTTER.
[PLOT-1
[PLOT X,Y,IC
[CALL JMP 4P
[    X
[    Y
[    IC
[NEXT INSTR.
[IC GIVES PEN
[CONTROL.
[O, +1, -1 =
[NO CHANGE
[+2,-2 =LOWER
[PEN
[+3,-3 =RAISE
[PEN
[PLOT CLOSED
[OUT IF IC IS
[LESS THAN ZERO
[THAT IS,NEG.
#4P LDA
0
BCLi
6000
STC 14
LDA 14
STC 4X
LDAi14
STC 4Y
LDAi14
STC 4Q
ADD 4P+3
ADD 4E
ADM
14
LDAi
#4Q 0
APO
COM
SHDi
0200
JMP 4N
SHDi
0300
JMP 4O
JMP 4Z
LDA
4Q
APOi
JMP 14
CLR
STC 3X
STC 3Y
JMP 14
[INTERP
[ROTATED 90
JMP 000
#4Z LDA
0
STC 4Z-1
STC 15
ADD 3X
COM
ADD 4X
STAi
#4A 0
APO
COM
STC 4B
ADD 3Y
COM
ADD 4Y
STAi
#4C 0
APO
COM
STC 4D
ADD 4D
COM
ADD 4B
APO
CLR
ADD 4D
AZEi
JMP 4Z-1
ROL 1
XSKi15
APOi
JMP p-3
LDAi
240
ADD 15
STC 4H
ADD 15
COM
ADAi
254
STC 4G
ADD 4E
#4G ROL 10
ADD 4E
COM
STC 15
ADD 4B
JMP 4H
STC 4B
ADD 4D
JMP 4H
STC 4D
STC 4M+3
STC 4M+11
#4M CLR
ADD 4B
LAMi
0
LZE
JMP 4J
CLR
ADD 4D
LAMi
0
LZE
JMP 4K
LDAi
#4I 0
APOi
JMP 4L
COM
STC 4I
ADD 4E
ADM
15
AZE
JMP 4M
JMP 4Z-1
#4X 0
#4Y 0
#4B 0
#4D 0
#4H ROL 4
JMP 0
#4J SET 17
0
LDA
4A
APO
JMP p+5
OPR 11
LDAi
#4E 1
JMP p+4
OPR 12
LDAi
#4F -1
ADMi
#3X 0
CLR
STC 4I
JMP 17
#4K SET 17
0
LDA
4C
APO
JMP p+5
OPR 10
LDA
4E
JMP p+4
OPR 7
LDA
4F
ADMi
#3Y 0
CLR
STC 4I
JMP 17
#4L SET 17
0
SETi16
1640
XSKi16
JMP p-1
JMP 17
[PEN DOWN
#4N SET 17
0
OPR 14
CLR
COM
STC 4R
SETi16
0
XSKi16
JMP p-1
SROi
3333
JMP 4N+6
JMP 17
[PEN UP
#4O SET 17
0
OPR 13
CLR
STAi
#4R 0
JMP 4N+6
[END OF INTERP
[ALPHAN
[MODIFIED
[FOR SIZE 3
[DIGITS 0-7.
[ENTER WITH
[DIGIT IN
[ACCUM.
JMP 000
#4U STAi
0
LDA
0
STC 4U-1
ADD 3X
STC 3C
ADD 3Y
STC 3D
ADD 4U+1
ADAi
p+11
STC p+2
LDA
0
ADAi
3777
STC 14
JMP 3A
JMP 4U-1
6A
6B
6C
6D
6E
6F
6G
6H
5Z
[BEGIN DIGITS
#6A 1202
1627
3746
4231
2112
0151
#6S 0000
#6B 0231
2127
1601
4100
#6C 1602
2737
4645
1211
4101
5100
#6D 1602
2737
4634
2434
4342
3121
1201
5100
#6E 3102
3713
4301
5100
#6F 1202
2131
4243
3414
1747
0151
0000
#6G 1302
2434
4342
3121
1216
2737
4601
5100
#6H 1702
4746
1101
5100
#5Z 1402
5401
6100
[END DIGITS
[DRAW SYMBOL
#3A LDA
0
STC p+3
LDHi14
AZEi
JMP 000
SHDi
0100
JMP 3L
SHDi
0200
JMP 3M
BCLi
7770
ADD 3Z
MUL
3B
ADD 3D
STC 4Y
LDH 14
BCLi
7707
SCR 3
ADD 3Z
MULi
#3B 3
ADD 3C
STC 4X
JMP 4Z
JMP 3A+3
#3Z -1
#3C 0
#3D 0
[PEN UP
#3L LDA
4R
APO
JMP 4O
JMP 3A+3
[PEN DOWN
#3M LDA
4R
APOi
JMP 4N
JMP 3A+3
$1177
[HERE IS LIST
7777
#2A 000
[TAG ASSIGNMENT
7Z=20
[END FOR NOW