Directory of image this file is from
This file as a plain text file

[TEXTPRNT
[A METHOD FOR PRINTING OUT TEXT MATERIAL, ENTERED VIA LAP-6.
[THE PROGRAM PRINTS OUT ON THE BUFFERED TELETYPE THE TEXT WHICH HAS BEEN ENTERED.
[ALL END OF LINE CHARACTERS ARE TREATED AS SPACES.
[THE $ SYMBOL IS USED TO INDICATE A NEW PARAGRAPH.
[NO WORD SPLITTING OR HYPHENATION IS PROVIDED.
[AJH OCT.1967
$20
LDAi
12
JMP 7P
SROi
3737
JMP p-5
[PICK UP FIRST BLOCK
LDAi
7351
STC 1A
RDC
7350
SETi1  [POINTER FOR CHARACTERS
7401
SETi5  [LINE COUNTER
-40
SETi4  [CHARACTERS PER LINE COUNTER
-103
SETi3  [PRINTER COUNTER
0
SETi2  [PRINT POINTER
1X+3777
#1E JMP 1B
LDHi1
SHDi
7700
JMP 1Z  [LAST CHARACTER
SHDi
6500
JMP 1C  [NEW PARAGRAPH
SHDi
1200
JMP 1D  [EOL, TREATED LIKE SPACE
SHDi
1400
JMP 1D  [SPACE
STHi2
XSKi3
XSKi4
JMP 1E
[LINE FILLED
#1F LDAi
12
JMP 7P
JMP 7P  [DOUBLE SPACED
LDAi
-103  [RESET CHARACTERS PER LINE COUNTER
ADD 3
STC 4
XSKi5
JMP 1E
#1G SETi5
-40   [RESET LINE COUNTER
LDAi
12
JMP 7P
SROi
3737
JMP p-5  [SPACING BETWEEN PAGES
JMP 1E
[NEW PARAGRAPH
#1C LDAi
12
JMP 7P
JMP 7P
LDAi
14
JMP 7P
SROi
3333
JMP p-5  [INDENT
SETi4
-100
XSKi5
JMP 1E-4
JMP 1G
[PRINT
#1D LDA
3
AZEi
JMP 1E
COM
STC 3
SETi2
1X+3777
LDHi2
JMP 7P
XSKi3
JMP p-3
LDAi
14
JMP 7P
XSKi4
JMP 1E-4
SETi3
0
SETi2
1X+3777
JMP 1F
[LAST CHARACTER
#1Z LDAi
12
JMP 7P
SROi
3737
JMP p-5
SETi15
RCG
SETi16
7300
JMP 15
[TEST FOR LAST CHARACTER IN BLOCK
#1B LDA
1
SAEi
7777
JMP 0
RDC
#1A 7351
LDAi
1
ADM
1A
SETi1
7377
JMP 0
[L6BUFTTY
[LAP 6 COMPATIBLE VERSION OF BUFFERED TELETYPE SUBROUTINES.
[READ AND PRINT
[ALPHANUMERICS
[SUBROUTINE.
[AJH REVISED
[JUNE 1967
[LAP 6 CHARACTER
[IN ACCUM.
[PRINT
#7P STC p+13
ADD 0
STC p+14
ADD p+10
ADAi
7L
STC p+2
LDA
0
OPRi2
LDAi
0
SAEi
12
JMP 000
SROi
5252
JMP p-3
LDAi
212
JMP p-13
[READ.LEAVES
[LAP 6 CHARACTER
[IN ACCUM.
#7R LDA
0
STC p+33
ADD 1
STC p+22
ADD 2
STC p+23
OPRi1
SETi1
-101
SETi2
7L-1
SAEi2
JMP p+21
LDAi
7L
COM
ADD 2
AZEi
COM
STC p+10
LDAi
0
STC 1
LDAi
0
STC 2
LDAi
0
JMP 000
XSKi1
JMP p-23
JMP p-14
[TABLE
#7L 260
261
262
263
264
265
266
267
270
271
215
377
240
246
247
255
253
257
243
215
301
302
303
304
305
306
307
310
311
312
313
314
315
316
317
320
321
322
323
324
325
326
327
330
331
332
251
000
277
275
245
254
256
244
333
300
336
273
274
276
335
252
272
207
[END SUBROUTINE L6BUFTTY.
[PRINT BUFFER
#1X 0
[END TEXTPRNT