Directory of image this file is from
This file as a plain text file

[ TFFTMOD
[ FROM TFFT
[TEST FOR THE FFT PGM
[READ IN FFT,OUTPUT PRINT,DISPLAY,AND COSINE SINE  INFORMATION
$20
UMB 3
RDC u  [FFT
4|1
RDC u
5|2
RDCu
6|3
RDC u
7|4
UMB 1 [PRINT OUT ARRAY
RDC u
4|5
RDC u
5|6
RDC u  [DBLFLT
6|7
RDC u
7|10
UMB 2 [DISPLAY
RDC u
4|30
RDC u  [FLOPD2
6|31
RDC u
7|32
UMB 4
RCG u  [MISC-2A
3|34
UMB 5
RCG u  [FILTER
3|44
UMB 6  [TANG TABL
RDC u
4|40
RDC u
5|41
JMP 1A
#1K JMP 1T [LO COS SIN TAB
LDA i
7777
LMB 3  [CALL FFT
JMP 20
JMP 1A
#1H CLR
ADD 1A+3
LMB 4  [FOR CODS A,L,G,T,S,B,R,M,
JMP 20
JMP 1A
$104
[CONTROL CENTER
#1A KBD i [PICK UP CODE
STC p+2
JMP p+2
XXX [CODE | E= ENTER DATA-P=PRINT ARRAY -DR=DISPLAY REAL-DI=DISPLAY IMAJ-F=DO FWD XFM-I=DO INV XFM-C=CLEAR INPUT ARRAY
LDA i
-30 [E
ADD 1A+3
AZE i
JMP 1C-2 [ENTER DATA
LDA i
-43  [P
ADD 1A+3
AZE i
JMP 1F [PRINT ARRAY
LDA i
-27 [D
ADD 1A+3
AZE i
JMP 1E
LDA i
-31 [FWD XFM
ADD 1A+3
AZE i
JMP 1K
LDA i
-34 [I
ADD 1A+3
AZE
JMP 1G
JMP 1T  [LO COS SIN TAB
LDA i [THIS IS INV XFM
0 [LOAD FWD CODE TO AC
LMB 3 [CALL FFT
JMP 20
JMP 1A [BRANCH TO CONTROL ON RETURN
$151
#1G LDA i
-26 [C
ADD 1A+3
AZE
JMP 1H  [CODS A,L,G,T,S,B,R,M
SET i1 [CLR DAT ARRAY
3777
CLR
#1L UMB 15
STA i1
UMB 16
STA 1
UMB 17
STA 1
XSK 1
JMP 1L
JMP 1A [FOR NEW COD
#1E KBD i [REAL OR IMAG DIS
STC 1A+3
LDA i
-45 [R
ADD 1A+3
AZE
JMP p+6
LDA i [REAL
0
LMB 2 [CALL DISPLAY
JMP 20
JMP 1A [ON RETURN
LDA i [IMAG
-1
JMP p-5
#1F LMB 1 [PRINT THE ARRAY
JMP 20
JMP 1A [ON RETURN
CLR [ENTRY TO ENTER DATA
STC p+7
#1C KBD i  [ENTER DATA IN ARRAY
STC 1D
RSW [ENTER ADDRESS
STC p+2
JMP p+3
XXX[NEW ADDR
XXX[LAST ADDR
ADD p-1
COM
ADD p-4
AZE i
JMP p+7  [EQUAL
CLR    [NEW ADDRESS INP
ADD 1C+5
STC 1C+6
ADD 1C+5
STC 6 [STORE ADDRESS
JMP p+2
LDA i 6 [NO CHANGE -JUST INDEX
LDA i
-53 [X - END OF INPUT
ADD 1D
AZE i
JMP 1A [GO TO CONTROL
CLR
ADD 1D
JMP 3A [CONVERT DAT
JMP 1J
JMP 2C [FEED LINE
[SPECIAL TEST FOR ZERO
LDA i
3777
ADD 7Z
AZE
JMP 1W [NOT ZERO
LDA
7Z+1
AZE
JMP 1W [NOT ZERO
LDA
7Z+2
AZE
JMP 1W [NOT ZERO
CLR [WRONG FORMAT FOR ZERO
STC 7Z [CORRECTED
#1W UMB 15
LDA
7Z
STA 6
UMB 16
LDA
7Z+1
STA 6
UMB 17
LDA
7Z+2
ROR 1
STA 6
JMP 1C [ENTER NEXT
#1J LDA i [ERROR IN INPUT DATA--CORRECT
-1
ADD 6
STC 6
JMP 1C
#1D XXX [TEMP STORAGE
#1T CLR
ADD 0
STC 1S
UMB 7 [COS SIN TAB
RDCu
4|12
RDC u
5|13
RDC u
6|14
RDC u
7|15
UMB 10
RDC u
4|16
RDC u
5|17
RDC u
6|20
RDC u
7|21
UMB 11
RDC u
4|22
RDC u
5|23
RDC u
6|24
RDC u
7|25
#1S X      [RETURN
[I
[CHANGE 2 TO ALLOW PRINTOUT ON BOTH LINC AND MICROLINC
$356
#2E CLR
ADD 2C-7
BCL i
7776
ATR
SET i 17
-430
XSK i 17
JMP p-1
LDA 
2C-7
SCR 1
STC 2C-7
SRO i
3777
JMP p-16
JMP 2C-1
[INPUT
[CONVERSION
$400
[INPUT NO.
[CONVERSION
#3A SET 15
0
JMP 4Z
ADD 3M
#3B SETi 13
-0
STC 3D
ADD 6F+2
STC 7Z
STC 7Z+1
STC 7Z+2
STC 16
JMP 5N
4B
-4D
ADD 3D
#3C SAEi
23
JMP p+3
KBDi
ADD 7I
STAi
#3D 0
SHDi
1300
JMP 15
SHDi
1200
JMP 3G
JMP 2A
ADD 3D
SHDi
1700
SETi 16
JMP p+1
SHDi
6100
XSKi 13
SAEi
#3Z 30
JMP 3F
XSKi 14
JMP 5N
-4F
ADD 16
STC 3M
KBDi
JMP 3B
#3F ADAi
-11
APOi
JMP 3E+4
CLR
ADD 3D
STC 4E+2
STC 4E+1
JMP 5O
-4E
XSK 13
JMP 3E+6
#3E JMP 5C
-4B
JMP 5A
-4E
KBDi
JMP 3C
JMP 5G
4E
4D
4E
JMP 5C
4D
4B
4D
JMP 3E+2
#3G XSK 14
JMP 3I
#3H CLR
ADD 16
APOi
JMP 3I-2
SETi 1
7Z
JMP 6D-2
XSKi 15
JMP 15
#3I JMP 5P
-7Z
AZE
JMP 6F-1
ADD 7Z+1
STC 4E
ADD 16
STC 4L
#3J JMP 4H
JMP 5C
4F
-4D
ADD 3M
JMP 3H+2
#3M 0
[CONSTANTS +
[SUBROUTINES
[LOG 2
[0.30103
#4A 7776
2321
0116
[10.0
#4B 0004
2400
0000
[TEM1
#4D 0
0
0
[TEM2
#4E 0
0
0
[TEM3
#4F 0
0
0
[1.0
#4G 0001
2000
0000
[10.0 TO
[THE |N|
[|N| IN 4E
[RESULT IN 4D
#4H SET 17
0
JMP 5N
4B
-7Z
JMP 5N
4G
-4D
#4I ADD 4E
AZEi
JMP 4M
SCRi 1
STC 4E
LZEi
JMP 4J
JMP 5C
4D
7Z
4D
#4J JMP 5C
-7Z
JMP 4I
#4M ADD 4L
APOi
JMP 17
JMP 5G
4G
4D
4D
JMP 17
#4L 0
LDAi
14
[6-BIT CODE
#2A ADAi
2D
STC 17
LDA 17
[TTYSUB
[PATCH 1 [
[MOD TO I AND O TO
[ALLOW PRINTOUT ON MICRO LINC
#2B STC 2C-7
ADD 0
STC 2C-1
MSC 4
APO i
JMP 2E
ADD 2C-7
SCR 1
OPR 42
JMP p-1
NOP
JMP p+2
XXX [DATA WORD
LDA i
7777
STC 2C-7
NOP
NOP
RTN
[EOL
#2C CLR
ADD 0
STC p+14
ADD 2D+12
JMP 2B
ADD 2D+13
JMP 2B
SETi 17
300
XSKi 17
JMP p-1
SROi
3567
JMP p-6
RTN
[CODES
#2D 7540
7542
7544
7546
7550
7552
7554
7556
7560
7562
7432
7424
7500
7514
7516
7532
7526
7536
7506
7416
7602
7604
7606
7610
7612
7614
7616
7620
7622
7624
7626
7630
7632
7634
7636
7640
7642
7644
7646
7650
7652
7654
7656
7660
7662
7664
7572
7612
7530
7534
7510
7666
#4Z STC 3M
LDAi
-13
STC 5P+7
SETi 14
-0
JMP 0
[DBLFLT
[FLOPSY
[L2Q2,3
[DOUBLE
[PRECISION
[FLTG. PT.
[SUBROUTINES
$1000
[ADD
#5A CLR
ADD 0
JMP 7A
LDA 1
COM
ADA 2
SKP 14
JMP p+4
SCR 14
BCOi
7737
SCRi 1
ROLi 1
LZEi
COM
STC 7M+1
JMP 6I
LZE
JMP 6H
LDA 1
STA 3
LDAi 2
STAi 3
LDAi 2
STAi 3
JMP 7M
JMP 7H
JMP 7I-2
JMP 6G
LDAi 3
JMP 6C+2
SET 1
6G+1
SETi 2
0
JMP 6D
JMP 7Q
[SUBTRACT
#5B CLR
ADD 0
JMP 7A
JMP 6I
JMP 6D-2
JMP 6H
JMP 5A+3
[MULTIPLY
#5C CLR
ADD 0
JMP 7A
LDA 1
ADA 2
JMP 6E+1
STC 5E
JMP 6C
JMP 6I
JMP 6D
JMP 6H
JMP 6D
LDAi 2
LDAi 2
ROR 1
STA 2
JMP 6H
LDAi 1
MULi 2
STA 3
MSC 5
STAi 3
LDAi 1
ROR 1
MULi 2
ROL 1
STAi 3
JMP 6H+2
LDAi 1
MUL 2
JMP 5F
#5D JMP 6H
LDAi 1
LDAi 1
ROR 1
MULi 2
JMP 5F
JMP 6G
LDAi 3
LDAi 3
ROLi 1
ROL 1
BCLi
7776
STC 7P
JMP 6G
LDAi 3
ROLi 1
STAi 3
JMP 6G
LDA 3
STAi 3
JMP 6G
LDAi
#5E 0
STA 3
JMP 7Q
#5F STC 7X
JMP 6B
STC 7X+1
SETi 1
7X-1
JMP 6G
JMP 7H
SETi 2
-0
JMP 7I
SROi
2525
JMP 5D
JMP 5D+6
[DIVIDE
#5G CLR
ADD 0
JMP 7A
ADD 7K
STC 5J+1
LDAi 2
AZEi
HLT
JMP 6H
LDA 2
COM
ADA 1
JMP 6E+1
JMP 6C
JMP 6H
JMP 6D
JMP 6I
JMP 6D
JMP 6H
LDAi 1
STAi 3
LDAi 1
STAi 3
LDAi 2
COM
STC 7X+1
LDAi 2
COM
STC 7X+2
STC 7X
STC 7Y
SETi 2
7X-3
#5H JMP 6H+2
JMP p+2
#5I JMP 6I+2
JMP 7H
#5J SROi
0001
JMP 5M
SETi 5
-0
JMP 6G
LDAi 3
AZE
JMP 5K-3
LDAi 3
AZEi
JMP 5K+2
CLR
JMP 6G
LDAi 3
#5K APO
JMP 5L
LDA 2
BSE
5J+1
STA 2
XSKi 5
#5L SET 1
6G+1
JMP 6G
JMP 7H
XSK 5
JMP 5H
JMP 5I
#5M XSKi 2
XSKi 2
XSKi 2
SROi
3333
JMP 5J+3
JMP 6G
CLR
ADD 7X
STAi 3
CLR
ADD 7Y
STAi 3
JMP 7Q
[MOVE 1 TO 2
#6A LDA 1
STA 2
LDAi 1
STAi 2
LDAi 1
STAi 2
CLR
JMP 0
[Z TO A
#6B MSC 5
ROL 1
SKP 15
ADD 7K
JMP 0
[COM SETUP
#6C LDAi 1
BCOi 2
ROLi 1
LDAi
NOP
LZE
ADD p+3
STC 7S
JMP 0
JMP 6D-20
SETi 2
-0
[COM|ABS 1
#6D LDAi 1
SCRi 1
ROLi 1
XSK 2
LZE
COM
STA 1
LDAi 1
XSK 2
LZE
COM
STA 1
JMP 0
[OVF CHECK
#6E ADA 3
AZEi
CLR
STA 3
SKP 14
JMP 0
APO
HLT
[RESULT=0
#6F JMP 6G
LDAi
-3777
STA 3
CLR
STAi 3
STAi 3
JMP 7T
[SET 3
#6G SETi 3
0
JMP 0
[SET NORMAL
#6H SETi 2
7Y+4000
SETi 1
7X
JMP 0
[SET REVERSE
#6I SETi 2
7X
SETi 1
7Y
JMP 0
[SETUP
#7A BCLi
6000
STC 4
ADD 0
STC 7E
LDA 4
JMP 7G
JMP 7F
STC 7C
LDAi 4
JMP 7G
JMP 7E+1
STC 7D
LDAi 4
JMP 7G
NOP
STC 6G+1
#7B JMP 6I
SETi 1
#7C 0
JMP 6A
XSKi 2
SETi 1
#7D 0
JMP 6A
XSKi 4
ADD 4
ADD 7A+1
STC 7T
STC 7P
JMP 6G
JMP 6H
#7E RTN
STC 7D
ADD 7F+2
JMP 7B-1
#7F STC 7D
LDAi
7Z
STC 7C
JMP 7E+2
[IR+SIGN TEST
#7G APOi
XSKi 0
APO
COM
ADAi
-17
SCRi 1
ROLi 1
ADD 7G+3
LZEi
JMP 0
STC 1
LDA 1
ADD 7S-1
STA 1
ADAi
-3
JMP 0
[ADD 1 TO 3
#7H SET 4
0
CLR
JMP 6G
LDAi 1
STC 7J
LDAi 3
STC 7J+2
LDA 1
LAM 3
LDAi 1
LAMi 3
JMP 6G
STC 0
LAMi 3
STC 0
LAMi 3
JMP 4
SETi 2
0
[CHECK FOR
[ADD OVERFLOW
#7I SET 1
0
JMP 6G
LDAi
#7J 0
BCOi
0
APO
JMP 1
LDAi 3
BCO
7J
APOi
JMP 1
JMP 6G
LDAi
#7K 1
JMP 6E
LDAi
#7L -1
XSK 2
JMP 7M+2
ADD 7P
XSK 2
COM
STC 7P
JMP 6G
LDAi 3
BCOi
4000
STA 3
JMP 1
[SCR N  3
#7M LDAi
0
SET 2
0
AZEi
JMP 2
STC 5
SETi 4
-30
#7O CLR
JMP 6G
LDAi 3
SCRi 1
STA 3
LDAi 3
RORi 1
STA 3
XSKi 4
JMP p+2
JMP p+3
XSKi 5
JMP 7O
JMP 6G
LDAi 3
ROLi 1
LZE
COM
STC 7P
JMP 2
#7P 0
[NORMALIZE,
[ROUND,XIT
#7Q CLR
STC 1
ADD 7P
RORi 1
JMP 6G
LDAi 3
SAEi 3
JMP p+5
AZE
JMP p+3
LZEi
JMP 6F
JMP 6G
LDAi 3
APO
JMP 7U
ROL 1
APOi
JMP 7T+1
#7R JMP 6G
LDAi 3
LDAi 3
RORi 1
STC 0
LAM 3
JMP 6G
STC 0
LAMi 3
APO
JMP 7V
JMP 6G
CLR
ADD 1
COM
JMP 6E
SET 1
3
#7S NOP
CLR
#7T XIT
LDAi 3
ROLi 1
STA 3
JMP 6G
LDAi 3
ROLi 1
STA 3
XSKi 1
JMP 7R-3
#7U JMP 7V
JMP 7R
#7V CLR
ADD 0
STC 7W
ADD 7L
JMP 7M+2
ADD 7L
ADD 1
STC 1
LDA 3
BCLi
4000
STA 3
#7W RTN
[ARG 1
#7X 0
0
0
[ARG 2
#7Y 0
0
0
[FAC
#7Z 0
0
0
[TRANSFER
#5N CLR
ADD 0
JMP 7A
SET 2
7D
JMP 6A
JMP 7T-1
[FLOAT
#5O CLR
ADD 0
JMP 7A
ADD 7D
STC 6G+1
JMP 6G
LDAi
27
STA 3
JMP 5B-10
[FIX
#5P CLR
ADD 0
JMP 7A
ADD 7D
STC 6G+1
JMP 6G
LDAi
-27
JMP 6E
APOi
JMP 7T
JMP 7M+2
JMP 7T-1
[END TFFTMOD
[XXXXXXXXX