Directory of image this file is from
This file as a plain text file

[TVCHANNEL
[SET RSW TO NO OF INPUTS AND PRESS N
[SET RSW TO MOD FACTOR AND PRESS M
[SET RSW TO INP BLK NO. AND PRESS T
[SET RSW TO OUTP BLK NO. AND PRESS S
[
[
UMB 3
RDC u [FFT
4|1
RDC u
5|2
RDC u
6|3
RDC u
7|4
UMB 4 [MISC-2A
RDG u
3|54
UMB 5 [FILTER
RDG u
3|64
UMB 6 [TAN TABLE
RDC u
4|40
RDC u
5|41
JMP 2A
#2H CLR
ADD 0
STC 2I
UMB 7 [COS|SIN TAB
RDC u
4|12
RDC u
5|13
RDC u
6|14
RDC u
7|15
UMB 10
RDC u
4|16
RDC u
5|17
RDC u
6|20
RDC u
7|21
UMB 11
RDC u
4|22
RDC u
5|23
RDC u
6|24
RDC u
7|25
#2I X
#2A KBD i
SAE i
41 [N
JMP 2A
RSW [NO OF INPUTS
COM
STC 5
KBDi
SAE i
40 [M
JMP 2A
RSW [MOD FACT
STC 10
KBDi
SAEi
47 [T
JMP 2A
RSW [INP BLK NO
STC 6
KBD i
SAE i
46 [S
JMP 2A
RSW
STC 7
LDA i
5252
STC p+2
#2G SRO i
X
JMP 2Q [QUA COMP
LDA i [IN PHA COM
314
STC 2B
LDA i
JMP 2D
STC 2C
LDA i
NOP
STC 2F
JMP 2P
#2Q LDA i
330
STC 2B
LDA i
NOP
STC 2C
LDA i
JMP 2K
STC 2F
#2P LDA
6
UMB 5
STA
3A
LDA i [ENTER DAT
47 [T
LMB 5 [CALL FILTER
JMP 20
JMP 2H [COS|SIN TAB
LDA i
7777
LMB 3 [CALL FFT
JMP 20
LDA i
24 [A
LMB 4 [CALL MISC-2A
JMP 20
LDA i
#2B X
UMB 5
STA
3A
LDA i [ENTER FILTER
25 [B
LMB 5
JMP 20
LDA i [FILTER SIGN
40 [M
LMB 5
JMP 20
#2C JMP 2D [OR NOP
LDA i
300 [HILB TX
UMB 5
STA
3A
LDA i [ENT HILB TX
25 [B
LMB 5
JMP 20
LDA i
40 [M
LMB 5
JMP 20
#2D LDA i [POLAR TO CART
45 [R
LMB 5
JMP 20
JMP 2H [COS|SIN TAB
LDA i
0
LMB 3 [CALL FFT
JMP 20
#2F NOP [OR JMP 1K
LDA [SAVE ON TP
7
UMB 4
STA
3B
LDA i
46 [S
LMB 4[CALL MISC-2A
JMP 20
JMP 2G
#2K JMP 2E [CALL DETECTOR
XSK i5
JMP p+2
JMP 2M 
CLR
ADD 6
ADA i
14
STC 6
ADD 7
ADD p-3
STC 7
JMP 2G
3A=2055
3B=2246
[
[DETECTOR
[WORKS WITH TVCHANN
#2E CLR
ADD 0
STC 3Z
LDA i [CHANG ADD IN SUB 2T
2R+2
JMP 2T
JMP 2R
#2T STA
2T+15
STC 2T+23
ADD 0
STC 2S
SET i17
-14
SET i16
-4
LDA 
7
STC 2T+21
LDA 
2R+2 [ADD SUBJ TO CHANG
BCL i
0777
ADAi
X [BLK NO
STA
2R+2
LDA
p-4
ADAi
1
STC p-7
XSK i17
JMP p+2
#2S X [RET
XSK i16
JMP  p+2
JMP p+5
ADD 2T+15
ADA i
2
JMP p+6
ADD 2T+15
ADAi
3
SET i16
-4
STA
2T+15
STC 2T+23
JMP 2T+14
[
[
#2R UMB 12 [RD X
RDC
4|100
RDC
5|101
RDC
6|102
RDC
7|103
UMB 13
RDC
4104
RDC
5|105
RDC
6|106
RDC
7|107
UMB 14
RDC
4|110
RDC
5|111
RDC
6|112
RDC
7|113
LDA
10
STC 2X+1
STC 2X
JMP 1I   [FLT M
2X 
2X
JMP 1D   [M|100
2X
2Z+3
2Z+6
JMP 1S   [100-M
2Z+3
2X
2X
#2J SET i17
2000
SET i16
2001
UMB 12 [PICK X
LDA 17
STC 2W
UMB 13
LDA 17
STC 2W+1
UMB 14
LDA 17
STC 2W+2
UMB 15 [PICK Y
LDA 17
STC 2Z
UMB 16
LDA 17
STC 2Z+1
UMB 17
LDA 17
 STC 2Z+2
JMP 1M     [M|100#Y=B
2Z
2Z+6
2Z
JMP 1M     [B##2
2Z
2Z
2Z
JMP 1M     [M|100#X
2W
2Z+6
2W
JMP 1A     [100-M+M|100#X=A
2W
2X
2W
JMP 1M     [A##2
2W
2W
2W
JMP 1A     [A##2+B##2
2W
2Z
2Z
JMP 1T     [SQRT A##2+B##2
2Z
2Z
UMB 15 [SAVE
LDA 
2Z
STA 17
CLR
STA 16
UMB 16
LDA
2Z+1
STA17
CLR
STA 16
UMB 17
LDA
2Z+2
STA17
CLR
STA 16
XSK i17
JMP p+2
JMP p+5
LDA i17    [IND 17
LDA i16    [IND 16
LDA i16    [IND 16
JMP 2J+4
LDA i
2L+2
JMP 2T
#2L UMB 15 [SAV ON TP
WRC
4|160
WRC
5|161
WRC
6|162
WRC
7|163
UMB 16
WRC
4|164
WRC
5|165
WRC
6|166
WRC
7|167
UMB 17
WRC
4|170
WRC
5|171
WRC
6|172
WRC
7|173
#3Z RETURN
#2X X     [M OR M-100
X
X
#2W X     [X
X
X
#2Z X     [Y
X
X
7     [CONST 100
2000
0000
X     [M|100
X
X
[
#2M KBD i [DIS
SAE i
27 [D
JMP 2M
KBDi
SAEi
45 [R
JMP p+4
CLR
STC 2N+1
JMP p+7
SAE i
34 [I
JMP 2M
LDA i
-1
STC 2N+1
UMB 1 [LO DIS PRO
RDC u
4|30
RDC u
6|31
RDC u
7|32
RSW
STC 7
LDA i
2O+2
JMP 2T
#2O UMB 15
RDC
4|100
RDC
5|101
RDC
6|102
RDC
7|103
UMB 16
RDC
4|104
RDC
5|105
RDC
6|106
RDC
7|107
UMB 17
RDC
4|110
RDC
5|111
RDC
6|112
RDC
7|113
#2N LDA i
X
LMB 1
JMP 20
JMP 2M
[XXXXXXXXXXXXXXXX
[XXXXXXXXXXXXXXXX
$1140
[SQRTND
[DOUBLE-PRECISION SQUARE ROOT
[USES NEWTON APPROXIMATION
[5 ITERATIONS
[
[USE FLOD-1R
[
[JMP 1T
[ADDR RADICAND
[ADDR RESULT
[USE XR 1,2,3,4
#1T LDA
0
JMP 1X-1
ADD 1R+1
STC p+67
LDA 2
STC p+71
LDA i2
STC p+67+1
LDA i2
STC p+65+2
ADD p+64+1
APO i [RADICAND NEGATIVE?
JMP p+7
COM
STC p+60+1
ADD p+57+2
COM
STC p+55+2
ADD p+54+1
 STC p+56+1
ADD p+52+2
STC p+54+2
ADD p+50
SCR 1 [EXP|2 FOR APPROX.
STC p+51
ADD p+50+1
AZE i
JMP p+24 [RESULT ZERO
CLR
ADD 3
STC p+22 
SET i4
-5
[N|X
 JMP 1D
p+34
p+36
p+27
[+ X[N]
JMP 1A
p+25
p+32
p+31
LDA i
-1
[DIVIDE RESULT BY TWO
ADD p+26
STC p+25
XSK i4
JMP p-15
[FINISHED CALCULATING
SET i3
 ADDR RESULT
LDA
p+17
STA 3
LDA 
p+14+1
STA i3
LDA
p+11+2
STA i3
 JMP RETURN
  0
0
0
  0
0
0
  0
0
0
[END SQRTND
[MJM 2-23-70
[FLOD-1R
[SUBTRACT, FLOAT, FIX
$1245
[ENTER SUBTRACT
#1S CLR
ADD 0
JMP 1X-2
LDA 2
STC 1M+112
LDA i2
COM
STC 1M+113
LDA i 2
COM
STC 1M+114
SET i2
1M+112
JMP 1A+3
[FLOAT INTEGER
#1I LDA i
26
APO
[FLOAT FRACTION
#1F CLR
STC 1M+112
STC 1N+15
ADD 0
JMP 1X-1
LDA 2
STC 1N+6
ADD 1M+112 [EXPONENT
STA 3
LDA i 2
ROL 1
STC 1N+1
ADD 1N+6
JMP 1A+73
[FIX INTEGER
#1J LDA i
-26
APO i
[FIX FRACTION
#1G CLR
STC 1M+60
STC 1N+15
ADD 0
JMP 1X-1
[CONTAINS ZERO ON RETURN
COM
ADD 1M+60
ADA 2
APO i
JMP 1H [OVERFLOW
XSK i 2
NOP
JMP 1A+111
STA 3
JMP 1R-7
[FLOD
[KERNEL
[PORTIONS FOLLOWING
[THIS POINT
[INTERACT STRONGLY
[WITH ONE ANOTHER
$1326
[ENTER MULTIPLY
#1M CLR
ADD 0
JMP 1X-2 [SET INDEX REGISTERS
LDA 2 [COMPUTE EXPONENT
ADA 1
JMP 1Q+3
STA 3
LDA i 2 [SET UP MULTIPLICANDS
STC 1M+113 [LEFT HALF
LDA i 2
STC 1M+112 [RIGHT HALF
LDA i 1
MUL [L1 X L2
4000+1M+113
AZE i
JMP 1H+1 [PRODUCT ZERO
LZE
COM
STC 1N+6
ZTA
STC 1N+1
LDA 1
MUL [L1 X R2
4000+1M+112
LZE
COM
ADM 
1N+1
ZTA
STC 1M+60
LZE
COM
STC 1N+15
LDA i 1
MUL [R1 X R2
4000+1M+112
LZE
COM
ADM 
1M+60
LDA 1
MUL [R1 X L2
4000+1M+113
LZE
COM
STC 0
ZTA
LAM i
0 [1M+60
BCL i 
3777
ROL i 2
LAM 
0
LAM
1N+1
BCL i
3777
ROL i 2
LAM 
1N+6
LDA
1M+60
ROL i 2
LDA 
1N+1
ROL i 1
STC 1N+1
[ CLEAR LINK
ROL i 1 [1M+104
JMP 1N [NORMALIZE
LDA i
-1
JMP 1Q+2 [DECREM EXPONENT
JMP p-4
[TEMPORARY
[STORAGE
0 [1M+112
0
0
[NORMALIZE STEP
#1N LDA i
0
LAM
p-2
SCR 14
LDA i
0
LAM
p-2
OVF
JMP 0
ROR i 1
BCO i
0
STA i 3
ROL i 1
ZTA
BCO
p-5
ROL 1
ROR i1
STA i 3
[NORMAL EXIT
#1R NOP      [*  #1R LDA i 4
JMP p    [*      JMP 4
[DIVIDE
#1D CLR
ADD 0
JMP 1X-2
[COMPUTE EXPONENT
LDA 2
COM
ADA 1
STA 3
JMP 1Q+3
JMP 1Q
[SET SIGN
LDA i 2
BCO i 1
SCR 14
STC 1N+15
[CLEAR QUOTIENT
STC 1N+1
STC 1N+6
LDA 2
AZE i
JMP 1H [DIVISOR ZERO
APO i
COM
BCL i 
4000 [1D+25
[LEFT DIVISOR
STC 1D+37
LDA i 2
APO i
COM
[CLEAR SIGN AND ADD +1
ADD 1D+25
ROL i 1
ROR 1
[RIGHT DIVISOR
STC 1M+112
LAM i
0 [1D+37
LDA 1
AZE i
JMP 1H+1
APO
COM
[LEFT DIVIDEND
STC 1D+100
LDA i 1
APO
COM
[RIGHT DIVIDEND
STC 1M+113
JMP 1D+105 [TRIAL SUB
APO
JMP p+10
LDA i
-1 [CONSTANT
JMP 1Q+2
JMP 1D+73 [DIVIDE LOOP
JMP 1D+105 [TRIAL SUB
APO i
JMP 1D+73
[SUBTRACTION SUCCEEDED
ROL i 1
STC 1D+100
ZTA
ROL 1
BCL i 
4000
JMP 1D+102
[SUBTRACTION FAILED
CLR [1D+73
ADD 1M+113
SCR 12
ADD p+2
ADM i
0 [1D+100
ZTA
STC 1M+113 [1D+102
JMP 1N
JMP 1D+61 [CLOSE LOOP
[TRIAL SUBTRACT SR
CLR [1D+105
ADD 1M+113
ADD 1M+112
ROR i 1
SCR i 12
ADD 1D+100
ADD 1D+37
JMP 0
[ENTER ADD
#1A CLR
ADD 0
JMP 1X-2
LDA 1
COM
ADA 2
OVF
JMP p+4
SCR 14 [1A+10
BCO i
-40
APO i
JMP 1A+101
STC 1M+60
STC 1N+15
[SET UP ADDITION
[REG1 POINTS TO
[ADDEND WITH LARGER
[EXPONENT
[
LDA 2
STC 1N+6 [SMALLER EXPONENT
LDA 1
STA 3 [LARGER EXPONENT
LDA i 2
LDA i1
AZE
JMP p+5
[ADDEND WITH LARGER
[EXPONENT IS ZERO
ADD 1N+6
STA 3
JMP 1A+101 [SWAP
[LOAD LEFT HALF
[OF LARGER
LDA 1
STC 1N+6
[LOAD RIGHT HALF OF LARGER
LDA i 1
ROL 1
STC 1N+1
[SCALE SMALLER
ADD 1M+60
JMP 1A+110
STC 1A+53
[CLEAR LINK
ROL i1
ZTA
ROL 1
ZZZ
ADD 1Q+1 [+1
[RIGHT + RIGHT
LAM 
1N+1
SCR 14
[LEFT + LEFT
LDA i
0    [1A+53
LAM
1N+6
OVF
JMP p+6
[OVERFLOW:INDEX EXP. AND SCALE RIGHT 1
JMP 1Q
LDA
1N+6
ROR i 1
JMP 1N+16 [EXIT
STC 0
LAM
1N+1
STC 0
LAM
1N+6
AZE    [1A+73
JMP 1M+104
SAE
1N+1
JMP 1M+104
JMP 1H+1 [ZER0 RESULT
[SWAP REG1 AND REG2
STC 1D+37 [1A+101
ADD 2
SET 2
1
STC 1
ADD 1D+37
JMP 0
[24-BIT SCALE
APO   [1A+110
COM   [1A+111
ADA i
-14
SCR i 1
ROL i 1
[IF SCALE>14, L=0
APO i
ADD p-4
APO i
CLR
ADD 1A+130
STC 1A+134
LDA 2
STC 1D+37
LDA i 2
ROL 1
SCR 14 [1A+130
ADD 1D+37
LZE i
SCR 14
SCR X  [1A+134
JMP 0
[SET INDEX REGISTERS
ADD 1Q+1 [+1
ADD 1Q+1
#1X ADD 1Q+1
STA
1R+1     [*    4
ADA i
-6003 [CONSTANT 1774
STC 3
LDA 3
STC 1
LDA i3
STC 2
LDA i3
STC 3
JMP 0
[ADJUST EXPONENT
#1Q LDA i
1
ADM 3
OVF
JMP 0
APO [SKIP IF UNDERFLOW
[ERROR STOP OR RETURN
#1H HLT      [*  #1H JMP 4
CLR
STA 3
STA i3
JMP 1R-1
[FLOD-1R
[5-8-69,21:00
[XXXXXXXXXXXXXXXXXX
[XXXXXXXXXXXXXXXXXX
[XXXXXXXXXXXXXXXX
[XXXXXXXXXXXXXXXX