Directory of image this file is from
This file as a plain text file

*20
/MAY 7, 1971
/DANIEL GRAY
/THIS PROGRAM WAS WRITTEN TO INTERFACE
/THE PDP-12 WITH THE MESSY DICK PUNCH
/AND READER.  IT IS WRITTEN TO HANDLE
/GLEN MARTINS DATA FORMAT, BUT CAN BE
/EASILY CHANGED TO BE MORE FLEXIBLE.
/PROGRAM ACCEPTS TTY INPUT IN FORMAT
/-H000H000H...-.  CARRIAGE RETURN
/WORKS AND RUBOUT WILL REMOVE PREVIOUS
/ENTRIES.  AFTER ALL DATA IS INPUT,
/TURN ON TTY PUNCH AND HIT PERIOD ON
/TTY.  THE PROGRAM PUNCHES OUT THE DATA
/WITH PARITY IN THE 8 BIT, ALWAYS 
/MAKING THE NUMBER OF BITS EVEN.
/SOURCE PROGRAM IS AS FOLLOWS:
/
/
	CLR
	LDF 1
	PDP
	PMODE
	JMP I .+1
	200
/
/
	*20
	CRLF=JMS .
	0
	CLA CLL
	TAD CR
	TYPE
	CLA CLL
	TAD LF
	TYPE
	CLA CLL
	JMP I .-10
	TYPE=JMS .
	0
	TSF
	JMP .-1
	TLS
	JMP I .-4
/
/
N20A,	-20
N20B,	-20
CR,	215
LF,	212
INC,	0
P200,	200
TEMP,	0
M4A,	-4
M4B,	-4
RN,	43
NRN,	-43
BSL,	37
NBSL,	-37
MRTSW,	0
IDISP,	DISP
INDEX,	0
F,	2000
/
/
	*200
	KCC
	TLS
BEGIN,	CLA CLL
	LAS
	RTL
	CIA
	DCA MRTSW
	TAD M4A
	DCA M4B
	TAD F
	DCA INDEX
	TAD BSL
	DCA I INDEX
	CRLF
	CRLF
INPUT,	KSF
	JMP .-1
	KRB
	SNA
	JMP .-4
	TYPE
	DCA TEMP
	DCA INC
	TAD TEMP
	RAL
	SZL
	ISZ INC
	CLL
	SZA
	JMP .-5
	TAD INC
	RAR
	SNL
	JMP .+5
	CLA CLL
	TAD P200
	TAD TEMP
	DCA TEMP
	CLA CLL
	TAD TEMP
	DCA I INDEX
	ISZ INDEX
	TAD BSL
	DCA I INDEX
	ISZ MRTSW
	JMP INPUT
	LAS
	RTL
	CIA
	DCA MRTSW
	CRLF
	TAD RN
	DCA I INDEX
	ISZ INDEX
	TAD BSL
	DCA I INDEX
	ISZ M4B
	JMP INPUT
	JMP I IDISP
OUTPUT,	CLA CLL
	TAD F
	DCA INDEX
	CLA CLL
	TAD N20A
	DCA N20B
	TYPE
	ISZ N20B
	JMP .-2
MO,	CLA CLL
	TAD I INDEX
	ISZ INDEX
	TAD NRN
	SNA
	JMP OUTPUT+3
	TAD RN
	TAD NBSL
	SNA
	JMP BEGIN
	TAD BSL
	TYPE
	JMP MO
DISP,	LINC
	LMODE
	SFA
	BCL I
	200
	ESF
START,	SET I 16
	3777
	SET I 14
	0
	SAM 0
	STC VERT
	SAM 4
	ADA I
	1000
	SCR 1
	ADA I
	2000
	STC CURVAL
	SET I 1
	20
CONT,	CLR
	SNS I 0
	JMP CUR
	SNS 1
	JMP CURR
	PDP
	PMODE
	JMP I IOUT
IOUT,	OUTPUT
	LMODE
CURR,	LDA I 16
	BCL I
	7700
	SAE I
	37
	SKP
	JMP START
	SAE I
	43
	SKP
	JMP RET
	ROL 1
	ADA I
	ZSTART
	STC 17
	LDA I
VERT,	0
	DSC 17
	DSC I 17
	LDA I
	4
	ADM
	1
	XSK I 14
	LDA
	14
	SAE I
	50
	JMP CONT
RET,	SET I 14
	0
	LDA I
	-40
	ADM
	VERT
	LDA I
	20
	STC 1
	JMP CONT
CUR,	LDA
	16
	SAE I
CURVAL,	0
	JMP CURR
	LDA I
	-4
	ADM
	1
	LDA I
	ZSTART+66
	STC 17
	LDA
	VERT
	DSC 17
	DSC I 17
	LDA I
	ZSTART+72
	STC 17
	LDA
	VERT
	DSC 17
	DSC I 17
	XSK I 15
	SKP
	JMP .+6 
	LDA I
	-14
	ADM
	1
	JMP CURVAL+2
	SET I 15
	-3
	LDA I
	-14
	ADM
	1
	KST
	JMP CURR
	PDP
	PMODE
CHAN,	KRB
	DCA TEMP
	DCA INC
	TAD TEMP
	RAL
	SZL
	ISZ INC
	CLL
	SZA
	JMP .-5
	TAD INC
	RAR
	SNL
	JMP .+5
	CLA CLL
	TAD P200
	TAD TEMP
	DCA TEMP
	CLA CLL
	TAD TEMP
	LINC
	LMODE
	STA I 16
	JMP CURR
/PATTERN WORDS FOR CHAR DISPL.
ZSTART,	4522            /AT SIGN
       	1645
   	4477		/A
	7744
	5177		/B
	2651
	4136		/C
	2241
	4177		/D
	3641
	4577		/E
	4145
	4477		/F
	4044
	4136		/G
	2645
	1077		/H
	7710
	7741		/I
	0041
	4142		/J
	4076
	1077		/K
	4324
	177		/L
	301
	3077		/M
	7730
	3077		/N
	7706
	4177		/O
	7741
	4477		/P
	3044
	4276		/Q
	376
	4477		/R
	3146
	5121		/S
	4651
	4040		/T
	4077
	177		/U
	7701
	176		/V
	7402
	677		/W
	7701
	1463		/X
	6314
	770		/Y
	7007
	4543		/Z
	6151
	4177		/[
	0000
	2040		/\
	0410
	0		/]
	7741
	2000		/^
	2077
	3410		/BACK ARROW
	1010
	0		/SPACE
	0
	7500		/!
	0
	6006		/"
	60
	3614		/NUMBER SIGN
	1436
	7721		/DOLLAR SIGN
	4677
	1446		/%
	6130
	5166		/&
	0523
	5000		/APOSTROPHY
	60
	4136		/(
	0
	0		/)
	3641
	2050		/*
	50
	404		/+
	437
	605		/,
	0
	404		/-
	404
	1		/.
	0
	601		//
	4030
	4136		/0
	3641
	2101		/1
	177
	4523		/2
	2151
	4122		/3
	2651
	2414		/4
	477
	5172		/5
	651
	1506		/6
	4225
	4443		/7
	6050
	5126		/8
	2651
	5120		/9
	3651
	4200		/:
	0
	2601		/;
	0
	2410		/<
	0042
	1212		/=
	1212
	4200		/>
	1024
	4020		/?
ZZEND,	2055
/END OF PATRNS TABLE