Directory of image this file is from
This file as a plain text file

[THIS PROGRAM WILL XFER DATA STORED ON LINC TAPE TO
[THE 160-G IN FORTRAN FORMAT, BCD AND BINARY
[1=HORIZONTAL POSITION FOR INFO DISPLAY
[2,3 = PTR FOR XFERRING DATA TO FORTRAN FORMAT
[5=HOR POS FOR DATA DISPLAY,PTR FOR INFO DISPLAY
[10=CTR FOR DATA DISPLAY
[11=PTR FOR TYPING
[12=12
[13=CTR, MISC
[14=PTR FOR DATA DISPLAY
[15=CTR FOR DEBINARIZATION
[16=CTR FOR SETTING DATA INTO FORTRAN BINARY FORMAT
[17=RETURN JMP INSTRUCTION FOR SUBROUTINE
9G=3006 [WRDCNT
CLR
STC 8A
SET i 12
12
SET i 11 [PTR FOR TYPING
1D-1
SET i 13 [CTR FOR TYPING
-7
LDA i 11
OPR 14 [TYP
XSK i 13
JMP p-3
#1F KBD i [LISN TO KB
SAE i [IS IT CR
12
JMP p+2 [NO
JMP 8B [YES
STC 1T
ADD 8A
ROL 3
ADD 1T
STC 8A
JMP 1F
#8B SET i 13
-2
LDA i
6000
ADM [ADD 6000 RDC ARGUMENT
8A
RDC u
#8A 0
XSK i 13 [SHOULD ANOTHER BLK BE READ IN
JMP p+2 [YES
JMP 8C [NO
LDA i
1001
ADM
8A
JMP 8A-1
#8C SET i 5 [DISPLAY DATA
1777
LDA
9G
COM
STA
2C
STC 10 [CTR 10 SET = TO -WRDCNT
SET i 14 [PTR FOR DATA DISPLAY
3007
#6G LDA i 14
ADA i 
-400
DIS i 5
XSK i 10 [IS DATA DISPLAY FINISHED
JMP 6G [NO
#6T SET i 1 [YES, DISPLAY INFO     1=HOR POS
100
SET i 2 [PTR FOR INFO DISPLAY
2777
SET i 13 [CTR TO DETERMINE IF DASH NECESSARY
-2
#6U CLR
XSK i 2
ADD 2
ADA i
-3003
APO i [BLKNO. DISPLAY
JMP 6Z [YES
SET i 3 [NO
-2
#6H LDA 2
XSK i 3
ROR 6
BCL i
7700
JMP 6J
XSK 3 [HAS LAST DIGIT OF # BEEN DISPLAYED
JMP 6H [NO, DISPLAY NEXT DIGIT
JMP 6N [YES, DISPLAY DASH.....NEXT WORD
JMP 6U
#6Z SAE i [IS INFO DISPLAY FINISHED
3
JMP p+2 [NO
JMP 2A [YES
SET i 3 [3=# OF DIGITS IN WORD
-3
#6P LDA 2
XSK i 3
ROR 3
XSK i 3
ROR 3
BCL i
7770
JMP 6J
XSK 3 [IS IT THE END OF #
JMP 6W [NO
LDA 2 [YES
BCL i
7770
JMP 6J
XSK i 13 [DONE
JMP 6N [NO
JMP 6U [YES
#6J SET i 17 [SUBROUTINE TO DISPLAY DIGIT
575
ROL 1 [SET UP PTR FOR DIGIT INVOLVED
ADA i
550
STC 5
ADA i VERTICAL POS
-300
DSC 5
DSC i 5
DSC 17
JMP 0
#6N SET 17 [SUBROUTINE TO DISPLAY DASH
0
SET i 5
573
SET i 3
-2
DSC i 5
XSK i 3
JMP p-2
JMP 17
#6W SET i 3
-2
JMP 6P
#1D 215
212
302 [BLKN
314
313
316
272
#1K 0001
#1T 0000 [TEMP
#2A SNS 0 [SHOULD XFER START
JMP 8C [NO
SET i 2 [YES....2=PTR FOR PRE-OPERATED ON DATA
2777
SET i 3 [PTR FOR OPERATED ON DATA
#2J 577
SET i 13
-4
SET i 16 [-WRDCNT
#2C 0000
JMP 2S [DAY, MONTH, YEAR, EXPNO INTO BCD
XSK i 13
JMP p-2
SET i 13
-3
CLR
STC 15
JMP 2T [BLKNO, RATE, WRDCNT INTO BCD
XSK i 13
JMP p-4
LDA i 2 [3007 DOES NOT HAVE PERTINENT DATA
SNS i 5
COM
STA i 3
LDA i
17
STC 7T
STC 9Y [INIT PHYSICAL RECORD CTR
#2D SET i 13
-50
CLR
JMP 2L
STA 3 [FIRST WORD OF PHYSICAL RECORD
#2E CLR
JMP 2L
STA 3
LDA i 2
JMP 2L
STA 3
JMP 2L
STA 3
XSK i 16 [IS THIS LAST DATA WORD
JMP p+2 [NO
JMP 2F [YES
XSK i 13 [ HAVE THERE BEEN 50 WORDS
JMP 2E [NO
JMP 2G [YES, UPDATE LOGICAL RECORD CTR
JMP 2D
#2F CLR
XSK i 13 [ LAST WORD, HAS 50 WORD LIST BEEN COMPLETED
JMP p+2 [NO
JMP 2H [YES
JMP 2L
STA 3
JMP 2L
STA 3
JMP 2L
STA 3
JMP 2F
#2H JMP 2G
LDA
3
ADA i
-170
STC 3A
ADD 7T
STA
#3A 0000 [ADDRESS OF FIRST WRD OF LAST LOGICAL RECORD
LDA  [FIND # OF WORDS TO BE XFERRED
2J
COM
ADD 3
STC 9W
LDA i
4500
JMP p-2
#2G LDA [UPDATE FIRST WORD OF LAST LOGICAL RECORD
2K
ADM
7T
CLR [INCREMENT PHYSICAL RECORD CTR
ADD 1K
ADM
9Y
JMP 0
#2L STC 1T [SUBROUTINE TO INCREMENT PTR
ADD 1K
ADM
3
LDA [RESTORE CONTENTS OF -A- REG
1T
JMP 0
#2S LDA i 2
BCL i
0077
ROR 6
AZE i
ADD 12
STA i 3
LDA 2
BCL i
7700
AZE i
ADD 12
STA i 3
JMP 0
#2T SET 17
0
LDA i 2
ADA i
-144
APO i [SKP IF A REG NEG
JMP 2U
AZE i [SKP IF A REG NON ZERO
JMP 2U
JMP 2U+2
#2U XSK i 15 [15 CONTAINS # OF 100S IN OCTAL #
JMP p-10
ADA i
144
STC 1T
ADD 15
AZE i
ADD 12
STA i 3
CLR
STC 15
ADD 1T
ADA i
-12
APO i
JMP 2V
AZE i
JMP 2V
JMP 2V+2
#2V XSK i 15 [15 CONTAINS # 0F 10S IN OCTAL #
JMP p-10
ADA i
12
STC 1T
ADD 15
AZE i
ADD 12
STA i 3
LDA
1T
AZE i
ADD 12
STA i 3
JMP 17
#7T 0000
#2K 0020
$500
#4A 0000 [RETURN ADDRESS
7300 [CLA CLL
600+9X [TAD FWA
6414 [CLR AND LOAD LOCATION CTR
7200 [CLA
600+9W [TAD WRDCNT
6424 [CLR AND LOAD WRDCNT
6404 [LOAD DB, SET G INTERRUPT
6402 [SKP ON DATA IN DB A 0
JMP p-1200-1 [JMP .-1
7200 [CLA
600+9Y [TAD PHYSICAL RECORD CTR
6404 [LOAD DB AND SET G INTERRUPT
6402 [SKP ON DATA IN DB A 0
JMP p-1200-1 [JMP .-1
6422 [SKP ON OVRFLO
JMP p-1200-1 [JMP .-1
6421 [CLR OVRFLO
JMP -600+4A [JMP I 4A
$545
#9W 0000 [# OF WORDS TO BE XFERRED TO G
#9X 4600 [FWA
#9Y 0000 [PHYSICAL RECORD CTR
4136 [0
3641
2101 [1
0177
4523 [2
2151
4122 [3
2651
2414 [4
0477
5172 [5
0651
1506 [6
4225
4443 [7
6050
5126 [8
2651
5120 [9
3651
0404 [DASH
0000 [SPACE