File BOUNCE.PA (PAL assembler source file)

Directory of image this file is from
This file as a plain text file

/***** BOUNCE AC *****\
XLIST
T1ON=	6424
T1SKP=	6421
T1OFF=	6422
FIXTAB
XLIST
/BOUNCE AC LIGHTS INTERRUP
/USES DC08 CLOCK, OF COURSE
/MOVES EVERY .1 SEC!
/
/BY JOHN YOUNG 2/10/76
/
/

*.-.
	.
	DCA	AC
	KSF
	SKP
	JMP	TTY
	T1SKP
	JMP	EXIT
	JMP	CLOCK

AUX,	0
N67,	-67
AC,	0
COUNT,	0
CTRC,	-3
MASK,	177
K4001,	4001

*0020
DOT,	JMP	DOT

CLOCK,	ISZ	COUNT
	JMP	EXIT
	TAD	N67
	DCA	COUNT
RESRET,	TAD I	AUX
	SNA
	JMP	RESET
EXIT,	TAD	AC
	T1ON
	ION
	JMP	DOT

RESET,	TAD	LSTPNT
	DCA	AUX
	JMP	RESRET

TTY,	KRB
	AND	MASK
	TAD	CTRC
	SZA CLA
	JMP	EXIT
	T1OFF
	TAD	CHARS
	DCA	AUX
	TAD I	AUX
	TLS
	TSF
	JMP	.-1
	SMA CLA
	JMP	.-5
	JMP I	.+1
	7605

START,	KCC
	TAD	LSTPNT
	DCA	AUX
	TAD	N67
	DCA	COUNT
	TAD	K4001
	JMP	EXIT+1

CHARS,	.;"^;"C;15;4012

/THIS LIST CAN BE PATCHED (!!!)
LSTPNT,	.
	6001
	7002
	7404
	7610
	7720
	0060
	0170
	0374
	0776
	1777
	0000	/END OF TABLE

$$$



Feel free to contact me, David Gesswein djg@pdp8online.com with any questions, comments on the web site, or if you have related equipment, documentation, software etc. you are willing to part with.  I am interested in anything PDP-8 related, computers, peripherals used with them, DEC or third party, or documentation. 

PDP-8 Home Page   PDP-8 Site Map   PDP-8 Site Search