/HI- HI- HILFE !!
/
	BSW=7002
/
	*10
K2,	2
K212,	212
K215,	215
K220,	220
KM377,	-377
KONST1,	377-215
KONST2,	215-203
KONST3,	203-220
KNPIP,	NPIP
K7700,	7700
TYPE,	0
	JMS CRLF
	TAD I TYPE
	JMS .+6
	TAD I TYPE
	BSW
	JMS .+3
	ISZ TYPE
	JMP TYPE+2
	0
	AND K7700
	SZA
	JMP .+3
	ISZ TYPE
	JMP I TYPE
	SMA
	IAC
	TAD K2
	BSW
	JMS OUT
	JMP I .-13
OUT,	0
	TLS
	TSF
	JMP .-1
	CLA CLL
	JMP I OUT
CRLF,	0
	TAD K215
	JMS OUT
	TAD K212
	JMS OUT
	JMP I CRLF
ECHO,	0
	KSF
	JMP .-1
	KRB
	TAD KM377
	SNA
	JMP I ECHO
	ISZ ECHO
	TAD KONST1
	SZA
	JMP .+3
	JMS CRLF
	JMP I ECHO
	ISZ ECHO
	TAD KONST2
	SNA
	JMP I PMONIT
	TAD KONST3
	SNA
	JMP .+6
	TAD K220
	TLS
	TSF
	JMP .-1
	JMP I ECHO
	JMS CRLF
	TAD KNPIP
	DCA .+6
	DCA .+6
	IAC
	CIF 10
	JMS I PUSR
	2
	NPIP
	0
	JMS ERROR
	TAD .-3
	DCA .+4
	CIF 10
	JMS I PUSR
	6
	0
/
NPIP,	FILENAME PIP.SV
PUSR,	200
PDEV,	0
ENTDEV,	0
WEICHE,	0
ZAEHL,	0
PNAME,	0
NAME1,	0;0;0;0
NAME2,	0;0;0;0
DEVNR,	0
PDIR,	0
ZAEHL1,	0
POINTR,	0
POINT1,	0
BEGBLK,	0
STEP,	0
ENTSYS,	7607
PMONIT,	7600
/
ERROR,	0
	CLA CLL
	CIF 10
	JMS I PUSR
	13
	CLA CLL
	TAD .-6
	HLT
	EJECT
	PAGE
	KCC
	CDF 00
	CIF 10
	JMS I K7700
	10
DEVIN,	JMS TYPE
	TEXT /DEVICE: /
	DCA DEV
	DCA DEV+1
	TAD (DEV
	DCA PDEV
	TAD (-4
	DCA ZAEHL
	CLL CMA RAL
	DCA WEICHE
NEXT1,	JMS ECHO
	JMP DEVIN
	JMP FETCH
	AND (77
	ISZ WEICHE
	JMP NEXT2
	TAD I PDEV
	DCA I PDEV
	CLL CMA RAL
	DCA WEICHE
	ISZ PDEV
	JMP .+3
NEXT2,	BSW
	DCA I PDEV
	ISZ ZAEHL
	JMP NEXT1
	JMS CRLF
FETCH,	TAD (1001
	DCA DEV+2
	CIF 10
	JMS I PUSR
	1
DEV,	0
	0
	0
	JMS ERROR
	TAD DEV+1
	DCA DEVNR
	TAD DEV+2
	DCA ENTDEV
OLDNA,	JMS TYPE
	TEXT /OLD NAME: /
	DCA NAME1
	DCA NAME1+1
	DCA NAME1+2
	DCA NAME1+3
	TAD (NAME1
	DCA PNAME
	JMS RDNAME
	JMP OLDNA
NEWNA,	JMS TYPE
	TEXT /NEW NAME: /
	DCA NAME2
	DCA NAME2+1
	DCA NAME2+2
	DCA NAME2+3
	TAD (NAME2
	DCA PNAME
	JMS RDNAME
	JMP NEWNA
	TAD NAME2
	SNA
	TAD NAME2+1
	SNA
	TAD NAME2+2
	SNA
	TAD NAME2+3
	SNA CLA
	JMP DELETE
	TAD NAME2+3
	TAD (-2331
	SZA CLA
	JMP CHANGE
	JMP TRANSF
RDNAME,	0
	CLA CLL CMA RAL
	DCA WEICHE
	TAD (-10
	DCA ZAEHL
NEXT3,	JMS ECHO
	JMP I RDNAME
	JMP RETR
	AND (77
	ISZ WEICHE
	JMP NEXT4
	TAD I PNAME
	DCA I PNAME
	ISZ PNAME
	CLL CMA RAL
	DCA WEICHE
	JMP .+3
NEXT4,	BSW
	DCA I PNAME
	ISZ ZAEHL
	JMP NEXT3
	JMS CRLF
RETR,	ISZ RDNAME
	JMP I RDNAME
/
	PAGE
DELETE,	TAD DEVNR
	CIF 10
	JMS I PUSR
	4
	NAME1
	0
	JMS ERROR
	JMP DEVIN
/
CHANGE,	TAD (NAME1
	DCA .+6
	DCA .+6
	TAD DEVNR
	CIF 10
	JMS I PUSR
	2
	NAME1
	0
	JMS ERROR
	TAD .-3
	SNA CLA
	JMS ERROR
	TAD (NAME2
	DCA PNAME
	CDF 10
	TAD I (1404
	TAD (-4
	TAD I (17
	DCA PDIR
	TAD I (7
	AND (7
	DCA SEGNR1
	CDF 00
	TAD (-4
	DCA ZAEHL
NEXT5,	TAD I PNAME
	CDF 10
	DCA I PDIR
	CDF 00
	ISZ PNAME
	ISZ PDIR
	ISZ ZAEHL
	JMP NEXT5
	JMS I ENTDEV
	4210
	1400
SEGNR1,	0
	JMS ERROR
	JMP DEVIN
	EJECT
TRANSF,	TAD (-6
	DCA ZAEHL
NEXT6,	TAD ZAEHL
	TAD (7
	DCA SEGNR2
	JMS I ENTDEV
	0200
	1400
SEGNR2,	0
	HLT CLA
	TAD I .-3
	DCA ZAEHL1
	TAD I (1404
	CIA
	TAD (4
	DCA STEP
	TAD I (1401
	DCA BEGBLK
	TAD (1405
	DCA POINTR
NEXT7,	TAD I POINTR
	SZA CLA
	JMP .+3
	ISZ POINTR
	JMP NEXT8
	TAD POINTR
	DCA POINT1
	TAD POINTR
	TAD STEP
	DCA POINTR
	TAD I POINTR
	SNA CLA
	JMP NEXT8
	TAD (NAME1
	DCA PNAME
	TAD (-4
	DCA WEICHE
	TAD I POINT1
	CIA
	TAD I PNAME
	SZA CLA
	JMP NEXT8
	ISZ POINT1
	ISZ PNAME
	ISZ WEICHE
	JMP .-10
	JMP FOUND
NEXT8,	TAD I POINTR
	CIA
	TAD BEGBLK
	DCA BEGBLK
	ISZ POINTR
	ISZ ZAEHL1
	JMP NEXT7
	TAD I (1402
	SNA CLA
	JMP NOTFND
	ISZ ZAEHL
	JMP NEXT6
	JMP NOTFND
/
	PAGE
/
FOUND,	TAD BEGBLK
	DCA INPBLK
	TAD I POINTR
	DCA ZAEHL1
	TAD ZAEHL1
	CIA
	DCA ARG2
FOUND1,	TAD (NAME2
	DCA ARG1
	DCA ARG1+1
	TAD ARG2
	CLL RTL
	CLL RTL
	IAC
	CIF 10
	JMS I PUSR
	3
ARG1,	0
	0
	JMS ERROR
	TAD ARG1
	DCA OUTBLK
NEXT9,	JMS I ENTDEV
	0200
	1400
INPBLK,	0
	JMS ERROR
	JMS I ENTSYS
	4200
	1400
OUTBLK,	0
	JMS ERROR
	ISZ INPBLK
	ISZ OUTBLK
	ISZ ZAEHL1
	JMP NEXT9
	CLA CLL IAC
	CIF 10
	JMS I PUSR
	4
	NAME2
ARG2,	0
	JMS ERROR
	JMP DEVIN
/
NOTFND,	JMS TYPE
	TEXT /BLOCKS (+49 SYS): /
	JMS RDNR
	JMP NOTFND
	TAD (7
	DCA INPBLK
NEXT10,	JMS TYPE
	TEXT /FILE-LENGTH: /
	JMS RDNR
	JMP NEXT10
	DCA ARG2
	TAD ARG2
	CIA
	DCA ZAEHL1
	JMP FOUND1
RDNR,	0
	DCA TEMP2
	CLL CMA RTL
	DCA ZAEHL
NEXT11,	JMS ECHO
	JMP I RDNR
	JMP RETR1
	TAD (-260
	DCA TEMP1
	TAD TEMP2
	CLL RTL
	RAL
	TAD TEMP2
	TAD TEMP2
	TAD TEMP1
	DCA TEMP2
	ISZ ZAEHL
	JMP NEXT11
	JMS CRLF
RETR1,	TAD TEMP2
	ISZ RDNR
	JMP I RDNR
TEMP1,	0
TEMP2,	0
/
	$$$$$$$$$$