Directory of image this file is from
This file as a plain text file

100 DIM M$(12,9),P(31,30),T(12),N$(30),U$(6,2)
110 LET Q=30\LET Q1=15
120 LET R1=0
130 FILEV#2:"LPT:"
140 FOR B=1 TO 12\ READ M$(B)\ NEXT B
150 FOR B=1 TO 6 \ READ U$(B)\ NEXT B
160 FOR I=1 TO 12 \ READ T(I)\ NEXT I
170 DATA "JANUARY","FEBRUARY","MARCH","APRIL","MAY","JUNE","JULY"
180 DATA "AUGUST","SEPTEMBER","OCTOBER","NOVEMBER","DECEMBER"
190 DATA "5 ","10","15","20","25","30"
200 DATA 31,28,31,30,31,30,31,31,30,31,30,31
210 IF R1 =1 THEN 230
220 GOTO 250
230 PRINT " DO YOU WISH TO CONTINUE? TYPE 1 FOR YES 0 FOR NO"\ INPUT A
240 IF A =0  THEN 2080
250 PRINT#2: TAB(25);"BIO-RHYTHM"
260 PRINT#2:TAB(6);"THE GRAPHS BELOW SHOW THE THREE CYCLES - PHYSICAL(X)"
280 PRINT#2: "EMOTIONAL (O),INTELLECTUAL (I) ,AND THE AVERAGE (*) - ON"
290 PRINT#2: "WHICH THE STUDY OF BIO-RHYTHM IS BASED. EACH OF US BEGINS"
300 PRINT#2: "EACH CYCLE AT BIRTH. EACH CYCLE HAS A CONSTANT LENGTH"
305 PRINT#2:"WITH THE PHYSICAL BEING 23 DAYS IN LENGTH; THE EMOTIONAL,"
310 PRINT#2:"28 DAYS IN LENGTH; AND THE INTELLECTUAL, 33 DAYS IN LENGTH."
313 PRINT#2:PNT(10);TAB(6);"THE 23-DAY CYCLE(X) EFFECTS ONE'S PHYSICAL"
316 PRINT#2:"STRENGTH, ENDURANCE, ENERGY, RESISTANCE, AND PHYSICAL"
319 PRINT#2:"CONFIDENCE. WHEN THE CURVE IS POSITIVE, A PERSON FEELS"
320 PRINT#2:"VIGOROUS AND HIS VITALITY AND ENDURANCE ARE AT THEIR"
330 PRINT#2:"BEST. WHEN THE CURVE IS NEGATIVE A PERSON OFTEN FINDS"
335 PRINT#2:"HIMSELF IN A PHYSICAL SLUMP, HAVING LESS RESERVE POWER,"
340 PRINT#2:"ENERGY OR ENDURANCE AND TIRING EASILY."
380 PRINT#2:PNT(10);TAB(6);"THE 28-DAY CYCLE(O) EFFECTS ONE'S NERVOUS"
385 PRINT#2:"SYSTEM. WHEN THE CURVE IS POSITIVE A PERSON IS MORE IN-"
390 PRINT#2:"CLINED TO OPTIMISM AND CHEERFULNESS. THIS PERIOD FAVOR-"
395 PRINT#2:"ABLY INFLUENCES CREATIVE ENTERPRISE, FEELINGS, LOVE,"
400 PRINT#2:"COOPERATION, AND ALL COORDINATION CONNECTED WITH THE"
405 PRINT#2:"NERVOUS SYSTEM. WHEN THE CURVE IS NEGATIVE A PERSON"
410 PRINT#2:"IS MORE INCLINED TO BECOME IRRITABLE AND NEGATIVE."
430 PRINT#2: PNT(10);TAB(6);"THE 33-DAY CYCLE ( I ) APPARENTLY ORIG-"
440 PRINT#2: "INATES IN THE BRAIN CELLS. WHEN THE CURVE IS POSITIVE"
450 PRINT#2: "ONE CAN THINK MORE CLEARLY, THE MEMORY FUNCTIONS WELL,"
460 PRINT#2: "AND MENTAL RESPONSE IS MOST SPONTANEOUS. THIS PERIOD"
470 PRINT#2: "IS CONSIDERED THE BEST TIME TO ABSORB NEW SUBJECTS"
480 PRINT#2: "AND FOR STUDYING AND CREATIVE THINKING. WHEN THE CURVE"
490 PRINT#2: "IS NEGATIVE THE CAPACITY TO THIMK IS REDUCED. GENERALLY,"
500 PRINT#2: "SUBJECTS, AS ABSORBING NEW MATERIAL IS MORE DIFFICULT"
510 PRINT#2: "DURING THIS TIME."
520 PRINT#2: PNT(10);TAB(6);"WHERE A SYMBOL ( X,O,I,* ) OCCURS AT THE"
530 PRINT#2: "CRITICAL LINE A PERSON IS EXPERIENCING A 'CRITICAL DAY'."
540 PRINT#2: "CRITICAL DAYS ARE THE FIRST DAY OF A NEW CYCLE AND THE"
550 PRINT#2: "DAY WHEN THE CYCLE CHANGES FROM POSITIVE TO NEGATIVE AND"
560 PRINT#2: "VICE VERSA. A PERSON SHOULD BE MORE CAREFUL DURING "
570 PRINT#2: "CRITICAL DAYS BECAUSE HIS SYSTEM SEEMS TO BE IN A STATE"
580 PRINT#2: "OF FLUX AND TO HAVE A CONSIDERABLE DEGREE OF INSTABILITY."
590 PRINT#2: "CRITICAL DAYS ARE 'IN THEMSELVES' NOT DANGEROUS. RATHER,"
600 PRINT#2:"THEY ARE DAYS DURING WHICH THE INDIVIDUAL'S REACTION TO "
610 PRINT#2: "HIS ENVIRONMENT MAY BRING ABOUT A CRITICAL SITUATION."
620 PRINT#2: "THEY SHOULD BE ACKNOWLEDGED MUCH THE SAME WAY AS A ROAD"
630 PRINT#2:"WARNING SIGN SUCH AS 'SLOW DOWN', 'SHARP CURVE AHEAD', AND"
650 PRINT#2: "'SLIPPERY WHEN WET'; THAT IS, POSSIBLE DANGER COULD OCCUR"
660 PRINT#2:"IF EXTRA CARE IS NOT TAKEN."
710 PRINT "INPUT PERSONS NAME"
720 INPUT N$
730 PRINT#2:PNT(12);TAB(15);"PLOT LEGEND"
740 PRINT#2: TAB(15);"PHYSICAL CYCLE = X"
750PRINT#2:TAB(15);"EMOTIONAL CYCLE = O"
760 PRINT#2:TAB(15);"INTELLECTUAL CYCLE = I"
770 PRINT#2: TAB(15);"AVERAGE CYCLE = *"
780 PRINT#2: PNT(10);TAB(15);"BIORHYTHM CHART FOR";PNT(32);N$
790  PRINT "PLEASE TYPE YOUR BIRTH DATE USING THE FOLLOWING FORMAT"
800  PRINT "MM,DD,YY. EXAMPLE JANUARY 17,1942=01,17,42"
810  INPUT M,D,Y
820 LET Y5=1900+Y
830 PRINT#2:PNT(10);TAB(15);"DATE OF BIRTH: ";M$(M);D;Y5
840  PRINT "AT WHAT DATE ARE INTERESTED IN BEGINNING BIORHYTHM?"
850  INPUT M1,D1,Y1
860  REM M=MONTH,D=DAY,Y=YEAR
870  REM D3=TOTAL NUMBER OF DAYS ELAPSED
880 REM T = DAYS IN EACH MONTH
890 A1=ASC("*")
900 S1=ASC("-")
910 S2=ASC("X")
920 S3=ASC("O")
930 S4=ASC("I")
940 S5=ASC(" ")
950  D3=0
960 REM- CHECK FOR PRESENT YEAR
970 IF Y1-Y > 0 THEN 1000
980 IF Y1-Y < 0 THEN 790
990 IF D=D1 THEN 1240
1000 IF M>2 THEN 1030
1010 IF INT(Y/4)-(Y/4) <> 0 THEN 1030
1020  D3 =1
1030 REM- CONTINUE
1040  D3=T(M)-D+D3
1050  FOR I=M+1 TO 12
1060  D3=T(I)+D3
1070  NEXT I
1080  REM Y3=YEAR COUNTER FROM BIRTH TO DISPLAY
1090  Y3=Y
1100  Y3=Y3+1
1110 IF Y3>=Y1 THEN 1170
1120 IF INT(Y3/4)-(Y3/4) = 0 THEN 1150
1130  D3=D3+365
1140 GOTO 1100
1150  D3=D3+366
1160 GOTO 1100
1170 IF M1<= 2 THEN 1200
1180 IF INT(Y1/4)-(Y1/4) <> 0 THEN 1200
1190  D3=D3+1
1200  FOR I=1 TO M1-1
1210  D3=T(I)+D3
1220  NEXT I
1230  D3=D1+D3
1240 LET M4=M1\LET Y4=Y1
1250 FOR L=1 TO 12
1260 FOR J=0 TO Q\FOR I1=1 TO 31
1270 LET P(I1,J)=S5\NEXT I1\NEXT J
1280 FOR L1=1 TO T(M4)
1290 F=(D3/23)-INT(D3/23)
1300 X=F*2*3.1416
1310 P1=(SIN(X)+1.0)*Q1
1320 F=(D3/28)-INT(D3/28)
1330 X=F*2*3.1416
1340 E=(SIN(X)+1.0)*Q1
1350 F=(D3/33)-INT(D3/33)
1360 X=F*2*3.1416
1370 I=(SIN(X)+1.0)*Q1
1380 D3=D3+1
1390 P(L1,Q1)=S1\V1=(P1+E+I)/3\V1=INT(V1+0.5)
1400 P1=INT(P1+0.5)\P(L1,P1)=S2
1410 E=INT(E+0.5)\P(L1,E)=S3
1420 I=INT(I+0.5)\P(L1,I)=S4
1430 P(L1,V1)=A1
1440 NEXT L1
1450 REM-PRINT CURRENT MONTH
1460 PRINT#2: PNT(12);TAB(27);M$(M4);" ";Y4;PNT(13)
1470 LET W=2\Z=3\Y=4
1480 FOR K=0 TO Q
1490 LET K1=Q-K
1500 IF K > 19 THEN 1820
1510 IF K <> 0 THEN 1540
1520 PRINT#2: TAB(W);"U";
1530 GOTO 1830
1540 IF K <> 1 THEN 1570
1550 PRINT#2: TAB(W);"P";
1560 GOTO 1830
1570 IF K <= 10 THEN 1830
1580 IF K <> 12 THEN 1610
1590 PRINT#2: TAB(W);"C";
1600 GOTO 1830
1610 IF K <> 13 THEN 1640
1620 PRINT#2: TAB(W);"R";
1630 GOTO 1830
1640 IF K <> 14 THEN 1670
1650 PRINT#2: TAB(W);"I";
1660 GOTO 1830
1670 IF K <> 15 THEN 1700
1680 PRINT#2: TAB(W);"T";
1690 GOTO 1830
1700 IF K <> 16 THEN 1730
1710 PRINT#2: TAB(W);"I";
1720 GOTO 1830
1730 IF K <> 17 THEN 1760
1740 PRINT#2: TAB(W);"C";
1750 GOTO 1830
1760 IF K <> 18 THEN 1790
1770 PRINT#2: TAB(W);"A";
1780 GOTO 1830
1790 IF K <> 19 THEN 1820
1800 PRINT#2: TAB(W);"L";
1810 GOTO 1830
1820 IF K > 26 THEN 1880
1830 PRINT#2: TAB(Z);":";TAB(Y);
1840 FOR R=1 TO 31\P1$=CHR$(P(R,K1))
1850 PRINT#2:P1$;PNT(32);\NEXT R
1860 IF K = 30 THEN 2000
1870 PRINT#2: PNT(13)\NEXT K\ GOTO 2080
1880 IF K <> 27 THEN 1910
1890 PRINT#2: TAB(W);"D";
1900 GOTO 1830
1910 IF K <> 28 THEN 1940
1920 PRINT#2: TAB(W);"O";
1930 GOTO 1830
1940 IF K <> 29 THEN 1970
1950 PRINT#2: TAB(W);"W";
1960 GOTO 1830
1970 IF K <> 30 THEN 1990
1980 PRINT#2: TAB(W);"N";
1990 GOTO 1830
2000 PRINT#2: PNT(13),TAB(Z);":";TAB(Y);
2010 FOR N3=1 TO T(M4)\PRINT#2:"-";PNT(32);\NEXT N3
2020 PRINT#2: PNT(13),TAB(Y);
2030 FOR U=1 TO T(M4)\IF U/5-INT(U/5)=0 THEN 2050
2040 PRINT#2: PNT(32);PNT(32);\GOTO 2060
2050 PRINT#2: U$(U/5);
2060 NEXT U
2070 GOTO 1870
2080 LET M4=M4+1
2090 PRINT#2: PNT(10);TAB(27);"DAYS OF THE MONTH"
2100 IF M4 <= 12 THEN 2120
2110 LET M4=1\Y4=Y4+1
2120 NEXT L
2130 PRINT#2: PNT(10);PNT(13);PNT(12)
2140 LET R1=1\ GOTO 210
2150 CLOSE#2
2160  END