Directory of image this file is from
This file as a plain text file

100 DIM M$(12,9),P(31,30),T(12),N$(30),U$(6,2)
110 LET Q=30\LET Q1=15
115 LET R1=0
120 FILEV#2:"LPT:"
121 FOR B=1 TO 12\ READ M$(B)\ NEXT B
122 FOR B=1 TO 6 \ READ U$(B)\ NEXT B
123 FOR I=1 TO 12 \ READ T(I)\ NEXT I
130 DATA "JANUARY","FEBRUARY","MARCH","APRIL","MAY","JUNE","JULY"
140 DATA "AUGUST","SEPTEMBER","OCTOBER","NOVEMBER","DECEMBER"
145 DATA "5 ","10","15","20","25","30"
146 DATA 31,28,31,30,31,30,31,31,30,31,30,31
147 IF R1 =1 THEN 149
148 GOTO 182
149 PRINT " DO YOU WISH TO CONTINUE? TYPE 1 FOR YES 0 FOR NO"\ INPUT A
150 IF A=0 THEN 1763
182 PRINT#2: TAB(25);"BIO-RHYTHM"
183 PRINT#2: TAB(6);"THE GRAPHS BELOW SHOW THE THREE CYCLES - PHYSICAL(X)"
184 PRINT#2: "EMOTIONAL (O),INTELLECTUAL (I) ,AND THE AVERAGE (*) - ON"
185 PRINT#2: "WHICH THE STUDY OF BIO-RHYTHM IS BASED. EACH OF US BEGINS"
186 PRINT#2: "EACH CYCLE AT BIRTH. EACH CYCLE HAS A CONSTANT LENGTH"
187 PRINT#2:"WITH THE PHYSICAL BEING 23 DAYS IN LENGTH; THE EMOTIONAL, 28 DAYS"
188 PRINT#2: "IN LENGTH; AND THE INTELLECTUAL, 33 DAYS IN LENGTH."
189 PRINT#2: PNT(10);TAB(6);"THE 23-DAY CYCLE ( X ) EFFECTS ONE'S PHYSICAL"
190 PRINT#2:"STRENGTH, ENDURANCE, ENERGY, RESISTANCE, AND PHYSICAL CONFIDENCE."
191 PRINT#2: "WHEN THE CURVE IS POSITIVE ,A PERSON FEELS VIGOROUS AND HIS"
192 PRINT#2: "VITALITY AND ENDURANCE ARE AT THEIR BEST. WHEN THE CURVE IS"
193 PRINT#2:"NEGATIVE A PERSON OFTEN FINDS HIMSELF IN A PHYSICAL SLUMP,HAVING"
194 PRINT#2: "LESS RESERVE POWER, ENERGY OR ENDURANCE AND TIRING EASILY."
195 PRINT#2:PNT(10);TAB(6);"THE 28-DAY CYCLE ( O ) EFFECTS ONE'S NERVOUS"
196 PRINT#2:"SYSTEM. WHEN THE CURVE IS POSITIVE A PERSON IS MORE INCLINED TO "
197 PRINT#2: "OPTIMISM AND CHEERFULNESS. THIS PERIOD FAVORABLY INFLUENCES"
198 PRINT#2: "CREATIVE ENTERPRISE, FEELINGS, LOVE, COOPERATION, AND ALL CO-"
199 PRINT#2: "ORDINATION CONNECTED WITH THE NERVOUS SYSTEM. WHEN THE CURVE "
200 PRINT#2: "IS NEGATIVE A PERSON IS MORE INCLINED TO BECOME IRRITABLE AND"
201 PRINT#2: "NEGATIVE."
205 PRINT#2: PNT(10);TAB(6);"THE 33-DAY CYCLE ( I ) APPARENTLY ORIG-"
210 PRINT#2: "INATES IN THE BRAIN CELLS. WHEN THE CURVE IS POSITIVE"
215 PRINT#2: "ONE CAN THINK MORE CLEARLY, THE MEMORY FUNCTIONS WELL,"
220 PRINT#2: "AND MENTAL RESPONSE IS MOST SPONTANEOUS. THIS PERIOD"
225 PRINT#2: "IS CONSIDERED THE BEST TIME TO ABSORB NEW SUBJECTS"
230 PRINT#2: "AND FOR STUDYING AND CREATIVE THINKING. WHEN THE CURVE"
235 PRINT#2: "IS NEGATIVE THE CAPACITY TO THINK IS REDUCED. GENERALLY,"
245 PRINT#2: "SUBJECTS, AS ABSORBING NEW MATERIAL IS MORE DIFFICULT"
250 PRINT#2: "DURING THIS TIME."
255 PRINT#2: PNT(10);TAB(6);"WHERE A SYMBOL ( X,O,I,* ) OCCURS AT THE"
260 PRINT#2: "CRITICAL LINE A PERSON IS EXPERIENCING A 'CRITICAL DAY'."
265 PRINT#2: "CRITICAL DAYS ARE THE FIRST DAY OF A NEW CYCLE AND THE"
270 PRINT#2: "DAY WHEN THE CYCLE CHANGES FROM POSITIVE TO NEGATIVE AND"
275 PRINT#2: "VICE VERSA. A PERSON SHOULD BE MORE CAREFUL DURING "
280 PRINT#2: "CRITICAL DAYS BECAUSE HIS SYSTEM SEEMS TO BE IN A STATE"
285 PRINT#2: "OF FLUX AND TO HAVE A CONSIDERABLE DEGREE OF INSTABILITY."
290 PRINT#2: "CRITICAL DAYS ARE 'IN THEMSELVES' NOT DANGEROUS. RATHER,"
295 PRINT#2:"THEY ARE DAYS DURING WHICH THE INDIVIDUAL'S REACTION TO "
296 PRINT#2: "HIS ENVIRONMENT MAY BRING ABOUT A CRITICAL SITUATION."
297 PRINT#2: "THEY SHOULD BE ACKNOWLEDGED MUCH THE SAME WAY AS A ROAD"
298 PRINT#2: "WARNING SIGN SUCH AS 'SLOW DOWN', 'SHARP CURVE AHEAD', AND"
299 PRINT#2: "'SLIPPERY WHEN WET'; THAT IS, POSSIBLE DANGER COULD OCCUR"
300 PRINT#2: "IF EXTRA CARE IS NOT TAKEN. ";PNT(10);PNT(13);PNT(10)
301 PRINT#2: TAB(1);"NOTE:";PNT(10)
302 PRINT#2: "BECAUSE OF THE NATURE OF THE EMOTIONAL CYCLE, A PERSON'S"
304 PRINT#2: "CRITICAL DAYS FOR THAT CYCLE WILL ALWAYS FALL ON THE SAME"
305 PRINT#2: "DAY OF THE WEEK ON WHICH THEY WERE BORN."
306 PRINT#2: PNT(10);PNT(10);PNT(10)
307 PRINT#2: "KEEP US IN MIND WHEN SEARCHING FOR AN INEXPENSIVE, "
308 PRINT#2: "ENTERTAINING, IMAGINATIVE GIFT."
310 PRINT "INPUT PERSONS NAME"
320 INPUT N$
325 PRINT#2:PNT(12);TAB(15);"PLOT LEGEND"
326 PRINT#2: TAB(15);"PHYSICAL CYCLE = X"
327PRINT#2:TAB(15);"EMOTIONAL CYCLE = O"
328 PRINT#2:TAB(15);"INTELLECTUAL CYCLE = I"
329 PRINT#2: TAB(15);"AVERAGE CYCLE = *"
330 PRINT#2: PNT(10);TAB(15);"BIORHYTHM CHART FOR";PNT(32);N$
350  PRINT "PLEASE TYPE YOUR BIRTH DATE USING THE FOLLOWING FORMAT"
360  PRINT "MM,DD,YY. EXAMPLE JANUARY 17,1942=01,17,42"
370  INPUT M,D,Y
374 LET Y5=1900+Y
375 PRINT#2:PNT(10);TAB(15);"DATE OF BIRTH: ";M$(M);D;Y5
380  PRINT "AT WHAT DATE ARE INTERESTED IN BEGINNING BIORHYTHM?"
390  INPUT M1,D1,Y1
430  REM M=MONTH,D=DAY,Y=YEAR
440  REM D3=TOTAL NUMBER OF DAYS ELAPSED
460 REM T = DAYS IN EACH MONTH
470 A1=ASC("*")
480 S1=ASC("-")
490 S2=ASC("X")
500 S3=ASC("O")
510 S4=ASC("I")
520 S5=ASC(" ")
530  D3=0
540 REM- CHECK FOR PRESENT YEAR
550 IF Y1-Y > 0 THEN 580
560 IF Y1-Y < 0 THEN 350
570 IF D=D1 THEN 820
580  IF M>2 THEN 610
590  IF INT(Y/4)-(Y/4)<>0 THEN 610
600  D3 =1
610 REM- CONTINUE
620  D3=T(M)-D+D3
630  FOR I=M+1 TO 12
640  D3=T(I)+D3
650  NEXT I
660  REM Y3=YEAR COUNTER FROM BIRTH TO DISPLAY
670  Y3=Y
680  Y3=Y3+1
690  IF Y3>=Y1 THEN 750
700  IF INT(Y3/4)-(Y3/4)=0 THEN 730
710  D3=D3+365
720  GOTO 680
730  D3=D3+366
740  GOTO 680
750  IF M1<=2 THEN 780
760  IF INT(Y1/4)-(Y1/4)<>0 THEN 780
770  D3=D3+1
780  FOR I=1 TO M1-1
790  D3=T(I)+D3
800  NEXT I
810  D3=D1+D3
820 LET M4=M1\LET Y4=Y1
830 FOR L=1 TO 12
840 FOR J=0 TO Q\FOR I1=1 TO 31
850 LET P(I1,J)=S5\NEXT I1\NEXT J
860 FOR L1=1 TO T(M4)
870 F=(D3/23)-INT(D3/23)
880 X=F*2*3.1416
890 P1=(SIN(X)+1.0)*Q1
900 F=(D3/28)-INT(D3/28)
910 X=F*2*3.1416
920 E=(SIN(X)+1.0)*Q1
930 F=(D3/33)-INT(D3/33)
940 X=F*2*3.1416
950 I=(SIN(X)+1.0)*Q1
960 D3=D3+1
970 P(L1,Q1)=S1\V1=(P1+E+I)/3\V1=INT(V1+0.5)
980 P1=INT(P1+0.5)\P(L1,P1)=S2
990 E=INT(E+0.5)\P(L1,E)=S3
1000 I=INT(I+0.5)\P(L1,I)=S4
1010 P(L1,V1)=A1
1020 NEXT L1
1030 REM-PRINT CURRENT MONTH
1035 PRINT#2: PNT(12);"BIO-RHYTHM CHART FOR ";N$
1036 PRINT#2:
1037 PRINT#2:
1040 PRINT#2: TAB(27);M$(M4);" ";Y4;PNT(13)
1041 PRINT#2:
1050 LET W=2\Z=3\Y=4
1060 FOR K=0 TO Q
1070 LET K1=Q-K
1080 IF K> 19 THEN 1400
1090 IF K <> 0 THEN 1120
1100 PRINT#2: TAB(W);"U";
1110 GOTO 1410
1120 IF K <> 1 THEN 1150
1130 PRINT#2: TAB(W);"P";
1140 GOTO 1410
1150 IF K <= 10 THEN 1410
1160 IF K <> 12 THEN 1190
1170 PRINT#2: TAB(W);"C";
1180 GOTO 1410
1190 IF K <> 13 THEN 1220
1200 PRINT#2: TAB(W);"R";
1210 GOTO 1410
1220 IF K <> 14 THEN 1250
1230 PRINT#2: TAB(W);"I";
1240 GOTO 1410
1250 IF K <> 15 THEN 1280
1260 PRINT#2: TAB(W);"T";
1270 GOTO 1410
1280 IF K <> 16 THEN 1310
1290 PRINT#2: TAB(W);"I";
1300 GOTO 1410
1310 IF K <> 17 THEN 1340
1320 PRINT#2: TAB(W);"C";
1330 GOTO 1410
1340 IF K <> 18 THEN 1370
1350 PRINT#2: TAB(W);"A";
1360 GOTO 1410
1370 IF K <> 19 THEN 1400
1380 PRINT#2: TAB(W);"L";
1390 GOTO 1410
1400 IF K > 26 THEN 1460
1410 PRINT#2: TAB(Z);":";TAB(Y);
1420 FOR R=1 TO 31\P1$=CHR$(P(R,K1))
1430 PRINT#2:P1$;PNT(32);\NEXT R
1440 IF K =30 THEN 1580
1450 PRINT#2: PNT(13)\NEXT K\ GOTO 1660
1460 IF K <> 27 THEN 1490
1470 PRINT#2: TAB(W);"D";
1480 GOTO 1410
1490 IF K <> 28 THEN 1520
1500 PRINT#2: TAB(W);"O";
1510 GOTO 1410
1520 IF K <> 29 THEN 1550
1530 PRINT#2: TAB(W);"W";
1540 GOTO 1410
1550 IF K <> 30 THEN 1570
1560 PRINT#2: TAB(W);"N";
1570 GOTO 1410
1580 PRINT#2: PNT(13),TAB(Z);":";TAB(Y);
1590 FOR N3=1 TO T(M4)\PRINT#2:"-";PNT(32);\NEXT N3
1600 PRINT#2: PNT(13),TAB(Y);
1610 FOR U=1 TO T(M4)\IF U/5-INT(U/5)=0 THEN 1630
1620 PRINT#2: PNT(32);PNT(32);\GOTO 1640
1630 PRINT#2: U$(U/5);
1640 NEXT U
1650 GOTO 1450
1660 LET M4=M4+1
1665 PRINT#2: PNT(10);TAB(27);"DAYS OF THE MONTH"
1681 PRINT#2:
1682 PRINT#2:
1683 PRINT#2:
1685 PRINT#2: "X = PHYSICAL CYCLE"
1690 PRINT#2: "O = EMOTIONAL CYCLE "
1695 PRINT#2: "I = INTELLECTUAL CYCLE "
1700 PRINT#2:
1705 PRINT#2:
1715 PRINT#2:
1720 PRINT#2: 
1725 PRINT#2: "AS OF THE LAST DAY OF ";M$(M4-1);" YOU HAVE LIVED A"
1730 PRINT#2: "TOTAL OF";D3;"DAYS."
1731 FOR F6 = 1 TO 6
1732 PRINT#2:
1733 NEXT F6
1734 PRINT#2: TAB(37);"SYSTEMS AND APPLIED SOFTWARE"
1735 PRINT#2: TAB(37);"SUITE 131"
1736 PRINT#2: TAB(37);"17311 EL CAMINO REAL"
1737 PRINT#2: TAB(37);"HOUSTON, TX.  77058"
1739 IF M4 <= 12 THEN 1741
1740 LET M4=1\Y4=Y4+1
1741 NEXT L
1742 PRINT#2: PNT(10);PNT(13);PNT(12);PNT(7)
1745 CLOSE#2
1750 LET R1=1
1755 FILEV#2:"LPT:"
1760 GOTO 147
1763 GOTO 1765
1765  END