Directory of image this file is from
This file as a plain text file

/	KL8-A (CHAN 0) 'RIM' LOADER FOR JENKEN SYSTEM
/	BY
/	SOFTWARE ENGINEERING  --  ANN ARBOR, MICHIGAN
/	R. L. COLE
/
	KCLR=6410	/CLEAR KL8-A
	KTST=6401	/TEST FOR I/O CHARACTER AVAILABLE/DONE
	KLRCV=6405	/READ INPUT CHAR INTO ACC, CLEAR INPUT FLAG
	KLBR=6412	/LOAD BRANCH BASE ADDRESS
	MQA=7501	/'OR' MQ INTO ACC
	LMQ=7421	/LOAD MQ FROM ACC, CLEAR ACC AFTER
/
	*7740
/
A,	JMS	C	/GET A CHARACTER
	CLL RTL		/SHIFT TO TEST FOR LEADER
	RTL
	SPA		/LEADER?
	JMP	A	/YES?
	RTL		/COMPLETES LEFT SHIFT OF 6 PLACES
	LMQ		/PUT FIRST CHARACTER OF FRAME AWAY FOR SAFE KEEPING
	JMS	C	/GET SECOND CHARACTER
	MQA		/MERGE IN FIRST CHAR
	SNL		/TEST FOR ORIGIN FRAME
	DCA I	F	/NO, DATA.  STORE IT.
B,	DCA	F	/SET ORIGIN (TO ZERO AFTER DATA WORD)
	JMP	A	/GO DO NEXT FRAME
F,	0		/ACTIVE ADDRESS POINTER
/
/	SUBROUTINE READS IN A CHARACTER
/
G,	D		/ADDRESS OF JUMP VECTOR BASE FOR KL8-A
C,	0
D,	KTST		/CHAR AVAILABLE?  [LINE 0 OUTPUT - IGNORE]
	JMP	D	/LINE 1 OUTPUT - IGNORE
	JMP	D	/LINE 2 OUTPUT - IGNORE
	JMP	D	/LINE 3 OUTPUT - IGNORE
/
	JMP	E	/LINE 0 INPUT - THIS IS WHAT WE ARE WAITING FOR
	NOP		/LINE 1 INPUT - IGNORE
	NOP		/LINE 2 INPUT - IGNORE
	KLRCV		/LINES 1, 2 & 3 INPUT - CLEAR FLAG
	JMP	D	/BUT OTHERWISE IGNORE
/
E,	KLRCV		/READ THE LINE 0 INPUT CHAR
	JMP I	C	/RETURN THE CHARACTER
/
/	START HERE
/
START,	KCLR		/CLEAR KL8-A
	TAD	G	/SET UP BRANCH ADDRESS
	KLBR
	JMP	A
	$