File LIFE.BA (BASIC source file)

Directory of image this file is from
This file as a plain text file

1 REM LIFE CLARK BAKER 3/72 C.O.G.
2  REMARKABLY TRANSLATED TO OS8 BASIC BY KAY R. FISHER ...DEC
3 X1=1\Y1=1\X2=24\Y2=70
4 PRINT "ENTER YOUR PATTERN - END BY "
5 PRINT "ANSWERING THE ?  WITH THE LETTER 'Z'"
10 DIM A(24,70),B$(24,24)
40 C=1
50 INPUT  B$(C)\IF SEG$(B$(C),1,1)="Z" GOTO 80
55 B$(C)=SEG$(B$(C),1,LEN(B$(C)))
60 C=C+1
70 GO TO 50
80 L=0\C=C-1
90 FOR X=1 TO C
100 IF LEN(B$(X))=<L THEN 110\L=LEN(B$(X))
110 NEXT X
120 X1=INT(11-C/2)
130 Y1=INT(33-L/2)
140 FOR X=1 TO C
150 FOR Y=1 TO LEN(B$(X))
160 IF SEG$(B$(X),Y,Y)=" " THEN 170\A(X1+X,Y1+Y)=1\P=P+1
170 NEXT Y
180 NEXT X
200 PRINT
210 PRINT "GENERATION:";G,"POPULATION:";P;\IF I9<>-1 GOTO 215\PRINT "INVALID!";
215 X3=24\Y3=70\X4=1\Y4=1\P=0
220 G=G+1
225 PRINT
230 FOR X=X1 TO X2
240 PRINT
250 FOR Y=Y1 TO Y2
253 IF A(X,Y)<>2 THEN 256\A(X,Y)=0\GO TO 270
256 IF A(X,Y)<>3 THEN 260\A(X,Y)=1\GO TO 261
260 IF A(X,Y)<>1 THEN 270
261 PRINT TAB(Y);"*";
262 IF X=>X3 GOTO 264\X3=X
264 IF X=<X4 GOTO 266\X4=X
266 IF Y=>Y3 GOTO 268\Y3=Y
268 IF Y=<Y4 GOTO 270\Y4=Y
270 NEXT Y
290 NEXT X
295 PRINT
296 PRINT"DO YOU WISH TO CONTINUE (1=YES, 0=NO)";\INPUT Q9\IF Q9=0 THEN 650
298 PRINT
299 X1=X3\X2=X4\Y1=Y3\Y2=Y4
301 IF X1>=3 THEN 303 \ X1=3\I9=-1
303 IF X2<=22 THEN 305 \X2=22\I9=-1
305 IF Y1>=3 THEN 307 \Y1=3\I9=-1
307 IF Y2=<68 THEN 309 \ Y2=68\I9=-1
309 P=0
500 FOR X=X1-1 TO X2+1
510 FOR Y=Y1-1 TO Y2+1
520 C=0
530 FOR I=X-1 TO X+1
540 FOR J=Y-1 TO Y+1
550 IF A(I,J)<1 GOTO 560\IF A(I,J)>2 THEN 560\ C=C+1
560 NEXT J
570 NEXT I
580 IF A(X,Y)=0 THEN 610
590 IFC=3 GOTO 595\IFC=4 GOTO 595\A(X,Y)=2\GOTO 600
595 P=P+1
600 GO TO 620
610 IF C<>3 THEN 620\A(X,Y)=3\P=P+1
620 NEXT Y
630 NEXT X
635 X1=X1-1\Y1=Y1-1\X2=X2+1\Y2=Y2+1
640 GO TO 210
650 END



Feel free to contact me, David Gesswein djg@pdp8online.com with any questions, comments on the web site, or if you have related equipment, documentation, software etc. you are willing to part with.  I am interested in anything PDP-8 related, computers, peripherals used with them, DEC or third party, or documentation. 

PDP-8 Home Page   PDP-8 Site Map   PDP-8 Site Search