File MFREQU.BA (BASIC source file)

Directory of image this file is from
This file as a plain text file

100 DIM A$(4),F$(20,1),K(1,20),G$(3),W(120)
101 DIM D$(8),Z$(1)
110 FILE#3:"DTA1:MSSHI.BA"
120 INPUT#3:D$,X
124 PRINT\PRINT\PRINT
130 PRINT"SOLLEN KURSFILES ERZEUGT WERDEN(JA ODER NEIN)";\INPUTA$
140 IF A$="NEIN" THEN 170
150 IF A$<>"JA" THEN 130
160 S1=1\Z1=0\Z2=0
170 INPUT#3:F,A,X,X
180 FORI=1TOF\INPUT#3:F$(I)\NEXTI
190 INPUT#3:X
200 FOR I=1TOF\INPUT#3:K(0,I)\NEXTI\INPUT#3:X,X
210 FOR I=1TO2\FORJ=1TOF+2\INPUT#3:X\NEXTJ\NEXTI
220 FOR I=1TOF\INPUT#3:K(1,I)\NEXT I
230 CLOSE#3
235 Z$=STR$(A)
240 GOSUB 410
245 FILE#1:"SYS:MSSMAT."&Z$&Z$
250 INPUT#1:Z,M,X,X,X
260 FOR I=1 TOF
270 FOR J=0 TO I-1\INPUT#1:X\NEXT J
280 FOR L1=1 TO M-1\INPUT#1:W(L1)
290 FOR L2=1 TO F+4\INPUT#1:X\NEXT L2
300 NEXT L1
310 INPUT#1:W(M)
320 RESTORE#1\FOR L3=1 TO 5\INPUT#1:X\NEXT L3
330 GOSUB 580
340 NEXT I
350 PRINT"ENDE DER AUSWAHL"
360 PRINT"SOLLEN NAMENSLISTEN GEDRUCKT WERDEN(JA ODER NEIN)"\INPUTA$
370 IF A$="NEIN" THEN 400
380 IF A$<>"JA" THEN 360
390 CHAIN"SYS:MKURNA.BA"
400 STOP
410 REM INHALTSVERZEICHNIS
420 PRINT"FUER FOLGENDE KURSE"
430 PRINT"DES JAHRGANGS 197";STR$(A)
440 PRINT "ES WERDEN AM ";D$;" LISTEN ERZEUGT"
450 FOR I=1 TO F
460 PRINT\PRINT F$(I)
470 FOR J=1 TO K(0,I)
480 PRINT J;
490 NEXT J
500 PRINT
510 FOR J= 1 TO K(1,I)
520 PRINT 4+J;
530 NEXT J\PRINT
540 NEXT I\PRINT\PRINT\PRINT\PRINT\PRINT
550 IF S1<>1 THEN 570
560 GOSUB 940
570 RETURN
580 REM DRUCK DER KURSLISTEN
590 PRINT\PRINT\PRINT
600 FOR L1 =0 TO 1
610 FOR L2=4^L1+L1 TO K(L1,I)+4*L1
620 PRINT "KURS:   ";F$(I);STR$(L2);TAB(30);D$
630 PRINT
640 Z1=0\Z2=0
650 FOR L3=1 TO 120
660 IF W(L3)=0 THEN 730
670 IF ABS(W(L3))<>L2 THEN 730
680 IF W(L3)>0 THEN 710
690 PRINT"*";
700 Z2=Z2+1
710 PRINT TAB(3);L3+A*1000
720 Z1=Z1+1
730 NEXT L3
740 PRINT\PRINTZ1;"SCHUELER,DAVON";Z2;"UEBER PFLICHTSTD.HINAUS"
750 PRINT\PRINT\PRINT
760 IF S1<>1 THEN 780
770 GOSUB 810
780 NEXT L2
790 NEXT L1
800 RETURN
810 REM KURSFILES AUF BAND
820 FILEV#2:"DTA1:"&F$(I)&STR$(L2)&"."&Z$&Z$
830 PRINT#2:Z1,Z2
840 FOR L3 = 1 TO 120
850 P=1
860 IF W(L3)=0 THEN 910
870 IF ABS(W(L3))<>L2 THEN 910
880 IF W(L3)>0 THEN 900
890 P=-1
900 PRINT#2:P*L3
910 NEXT L3
920 CLOSE#2
930 RETURN 
940 REM FILE FUER KURSBEZEICHNUNGEN
950 FILEV#4:"DTA1:MKURBZ."&Z$&Z$
960 FOR I=1 TO F
970 FOR J=1 TO K(0,I)
980 PRINT#4:F$(I)&STR$(J)
990 NEXT J
1000 FOR J=1 TO K(1,I)
1010 PRINT#4:F$(I)&STR$(4+J)
1020 NEXT J
1030 NEXT I
1040 CLOSE#4
1050 RETURN
1060 END



Feel free to contact me, David Gesswein djg@pdp8online.com with any questions, comments on the web site, or if you have related equipment, documentation, software etc. you are willing to part with.  I am interested in anything PDP-8 related, computers, peripherals used with them, DEC or third party, or documentation. 

PDP-8 Home Page   PDP-8 Site Map   PDP-8 Site Search