10 REM*** UMGESCHRIEBEN VON EBERHARD HUBIG          2/76
20 DIM R$(29)\R$ ="FALSCHE EINGABE,NEU EINGEBEN"
30 PRINT\PRINT\PRINT
40 PRINT"MONDLANDESIMULATION"\PRINT
50 PRINT"WOLLEN SIE ERLAEUTERUNGEN(JA ODER NEIN)";\INPUT A$
60 IF A$ = "NEIN" THEN 320\IF A$ = "JA" THEN 70\PRINT R$\GOTO 50
70 PRINT\PRINT"SIE LANDEN AUF DEM MOND UND HABEN DIE KONTROLLE DER";
80 PRINT" KAPSEL IN EINER","HOEHE ";
90 PRINT"VON 500 KILOMETERN UEBER DER LANDESTELLE UEBERNOMMEN.SIE HABE";
100PRINT"N","EINE DERZEITIGE FALLGESCHWINDIGKEIT VON 50 M/SEK.AUSSERDE";
110 PRINT"M HABEN SIE","NOCH 120 EINHEITEN TREIBSTOFF UEBRIG."\PRINT
120 PRINT"HIER SIND DIE REGELN,DIE IHNEN IHRE KAPSEL GIBT."
130 PRINT"(1)  NACH JEDER SEKUNDE WIRD IHNEN DIE DERZEITIGE HOEHE,";
140 PRINT"DIE","     MOMENTANE FALLGESCHWINDIGKEIT UND DIE MENGE DES ";
150 PRINT"UEBRIGGEBLIEBENEN","     TREIBSTOFFES MITGETEILT."
160 PRINT"(2)  NACH DIESEM BERICHT WIRD EIN '?' GEDRUCKT WERDEN.GEBEN ";
170 PRINT"SIE DIE","     ANZAHL DER EINHEITEN TREIBSTOFF AN,DIE IN DER";
180 PRINT" NAECHSTEN SEKUNDE","     VERBRAUCHT WERDEN SOLLEN.(JEDE ";
190 PRINT"EINHEIT TREIBSTOFF WIRD IHR"
200 PRINT"     ABSTEIGEN UM 1 M/SEK VERLANGSAMEN.)"
210 PRINT"(3)  DER MAXIMALE SCHUB IHRER KAPSEL IST 30 EINHEITEN TREIB";
220 PRINT"STOFF/SEK.","(4)  WENN SIE DIE MONDOBERFLAECHE BERUEHRT ";
230 PRINT"HABEN,SCHALTET SICH DAS","     BREMSTRIEBWERK AUTOMATISCH AB";
240 PRINT" UND SIE BEKOMMEN EINEN BERICHT","     UEBER IHRE LANDUNGS";
250 PRINT"GESCHWINDIGKEIT UND DEN RESTLICHEN TREIBSTOFF.","(5)  WENN ";
260 PRINT"IHNEN DER TREIBSTOFF AUSGEHEN SOLLTE,WIRD DAS '?' NICHT"
270 PRINT"     LAENGER ERSCHEINEN,DER SEKUENDLICHE BERICHT WIRD SICH ";
280 PRINT"ABER","     FORTSETZEN,BIS SIE DIE OBERFLAECHE ERREICHT";
290 PRINT" HABEN","(6)  WENN SIE KEINE WEICHE LANDUNG HINBEKOMMEN,SAGE";
300 PRINT" ICH IHNEN DIE"
310 PRINT"     TIEFE DES VON IHNEN VERURSACHTEN KRATERS."
320 PRINT"NUN BEGINNT DAS LANDEUNTERNEHMEN....."\PRINT
330 PRINT"       V I E L   G L U E C K   !!!!!"\PRINT\PRINT
340 PRINT"    SEK  METER  M/SEK  SPRIT    GRAPH DES MONDABSTANDES"
350 FOR I = 0 TO 70\PRINT TAB(I);"-";\NEXT I
360 PRINT" "
370 T = 0\H = 500\V= 50\F = 120
380 GOSUB 700
390 PRINT PNT(13);\INPUT B
400 IF B < 0 THEN 830\IF B > 30 THEN 830\IF B > F THEN 830
410 V1 = V - B + 5\F = F - B\H = H - 0.5 *(V + V1)\IF H <= 0 THEN 480
420 T = T + 1\V = V1
430 IF F > 0 THEN 380\IF B = 0 THEN 450
440 PRINT"*** TREIBSTOFFTANK LEER ***";TAB(29);"!";TAB(R);"*"
450 GOSUB 700
460 PRINT" "
470 B = 0 \GOTO 410
480 PRINT PNT(7);"***** BODENKONTAKT *****    *"
490 H = H + 0.5 *(V + V1)\IF B = 5 THEN 510
500 D = (-V + SQR(V*V+H*(10 - 2 * B)))/(5 - B)\GOTO 520
510 D = H/V
520 V1 = V +(5 - B)*D\PRINT"BERUEHRUNG NACH";T+D;"SEKUNDEN."
530 PRINT"AUFSETZGESCHWINDIGKEIT = ";V1;"M/SEK."
540 IF F>0 THEN 550\PRINT"KEIN TREIBSTOFF UEBRIG"\GOTO 560
550 PRINT F;"EINHEITEN TREIBSTOFF UEBRIG."
560 IF V1 <> 0 THEN 590
570 PRINT"HERZLICHEN GLUECKWUNSCH!!    EINE PERFEKTE LANDUNG!"
580 PRINT"IHRE LIZENZ WIRD ERNEUERT.....S P A E T E R.."\GOTO 670
590 IF ABS(V1) <= 4 THEN 660
600 PRINT"***** TUT MIR LEID,ABER SIE SIND ZERSCHELLT!!!!!*****"
610 PRINT"SIE HABEN EINEN KRATER VON";0.673952 * V1;"METERN TIEFE ";
620 PRINT"VERURSACHT!"
630 PRINT"PASSENDE BEILEIDSSCHREIBEN WERDEN AN IHRE NAECHSTEN  ";
640 PRINT"VERWANDTEN","ABGESCHICKT WERDEN!"
650 GOTO 670
660 PRINT"SIE SIND OHNE(GROSSERE)SCHAEDEN GELANDET!"
670 PRINT"EINE NEUE MISSION(J ODER N)";\INPUT A$
680 PRINT\PRINT\PRINT
690 IF A$  ="J" THEN  320\IF A$ = "N" THEN 840\PRINT R$\GOTO 670
700 R = INT(H/12 + 29.5)
710 IF T >= 10 THEN 720\PRINT TAB(6);T;\GOTO 730
720 PRINT TAB(5);T;
730 IF H>= 10 THEN 740\PRINT TAB(12);H;\GOTO 760
740 IF H >= 100 THEN 750\PRINT TAB(11);H;\GOTO 760
750 PRINT TAB(10);H;
760 IF ABS(V) >=10 THEN 770\PRINT TAB(19);V;\GOTO 780
770 PRINT TAB(18);V;
780 IF F >= 10 THEN 790\PRINT TAB(26);F;\GOTO 810
790 IF F >= 100 THEN 800\PRINT TAB(25);F;\GOTO 810
800 PRINT TAB(24);F;
810 PRINT TAB(29);"!";\IF R > 72 THEN 820\PRINT TAB(R);"*";
820 RETURN
830 PRINT R$;"!"\GOTO 390
840 END