Directory of image this file is from
This file as a plain text file

10 REM*** INS DEUTSCHE MIT KLEINEN AENDERUNGEN UEBERSETZT VON
20 REM*** EBERHARD HUBIG GUMMERSBACH          3/76
30 DIM R$(40),N$(9)
40 R$ = "FALSCHE EINGABE,BITTE NEU EINGEBEN!"\Z$="R"\B1=1
50 R3=0\A3=0\D9=3.2878E-04\M1=7.45\M0=M1\B=1000
60 M=17.95\F1=5.25\N=7.5\R0=926\V0=1.29\T=0\H0=60\R=R0+H0\A=-3.425
70 R1=0\A1=8.8436E-04\T1=0\F=0\P=0\N=1\M2=0\S=0\C=0\Z=1852.8\G5=1000
80 M$="METER"\N$="KILOMETER"\IF Z$="J" THEN 1070
90 PRINT\PRINT\PRINT\PRINT"MONDLANDESIMULATION 2"\PRINT
100 PRINT"SIND SIE SCHON EINMAL GEFLOGEN(J ODER N)";\INPUT Q$
110 IF Q$="J" THEN 330\IF Q$ = "N" THEN 130\PRINT R$\GOTO 100
120 PRINT\PRINT
130 PRINT"SIE SIND NUN BEI EINER MONDLANDEMISSION.ALS DER PILOT DER";
140 PRINT" MONDLANDE-","KAPSEL KOENNEN SIE BESTIMMTE BEFEHLE";
150 PRINT" AN DAS STEUERGERAET GEBEN.","DER BORDCOMPUTER WIRD IHNEN";
160 PRINT" DANN LAUFEND BESTIMMTE INFORMATIONEN,DIE","SIE ZUR ";
170 PRINT"STEUERUNG DES SCHIFFES BENOETIGEN,AUSDRUCKEN!"\PRINT
180 PRINT"DER WINKEL,NACH DEM GEFRAGT WIRD,BEZEICHNET DIE FLUGLAGE!";
190 PRINT"IHN KANN MAN","FOLGENDERMASSEN BESCHREIBEN:"
200 PRINT"180 ODER - 180 GRAD IST EIN WEG DIREKT VOM MOND WEG"
210 PRINT"- 90 GRAD IST AUF EINER DIREKTEN LINIE IN RICHTUNG WELTRAUM"
220 PRINT"90 GRAD IST AUF EINER LINIE AUS DER RICHTUNG VOM WELTRAUM"
230 PRINT"0 GRAD IST EIN WEG DIREKT IN RICHTUNG DES MONDES"\PRINT
240 PRINT TAB(30);"-180!180"\PRINT TAB(34);"!"
250 PRINT TAB(27);"- 90< -+- > 90"\PRINT TAB(34);"!"\PRINT TAB(34);"0"
260 PRINT TAB(27);"MONDOBERFLAECHE"\PRINT
270 PRINT"ALLE WINKEL ZWISCHEN - 180 UND + 180 GRAD SIND MOEGLICH!"
280 PRINT\PRINT"1 EINHEIT TREIBSTOFF REICHT FUER EINE SEKUNDE MAXIMALE";
290 PRINT"N SCHUB","DER SCHUB KANN GEWAEHLT WERDEN:"
300 PRINT"ER KANN 0 ODER JEDEN WERT ZWISCHEN 10 UND 100 PROZENT";
310 PRINT" ANNEHMEN"\PRINT
320 PRINT"KEINE NEGATIVE ZEIT ODER SCHUB EINGEBEN!"
330 PRINT
340 PRINT"EINGABE: ZEITINTERVALL IN SEKUNDEN----------(Z)"
350 PRINT"         PROZENTANGABE DES SCHUBES----------(P)"
360 PRINT"         FLUGLAGEWINKEL IN GRAD-------------(W)"\PRINT
370 PRINT"WENN SIE DIE MISSION ABBRECHEN WOLLEN,GEBEN SIE 0,0,0 EIN!"
380 PRINT
390 PRINT"AUSGABE: BIS JETZT VERSTRICHENE ZEIT IN SEKUNDEN"
400 PRINT"         HOEHE IN METER"
410 PRINT"         ENTFERNUNG VON DER LANDESTELLE IN METER"
420 PRINT"         VERTIKALE GESCHWINDIGKEIT IN M/SEK"
430 PRINT"         HORIZONTALE GESCHWINDIGKEIT IN M/SEK"
440 PRINT"         RESTLICHEN EINHEITEN TREIBSTOFF"
450 PRINT\PRINT
460 PRINT" ZEIT   HOEHE      ENTFERNUNG   VERT. GES.   HORI. GES.";
470 PRINT"    TREIBSTOFF"
480 FOR N = 0 TO 70\PRINT TAB(N);"-";\NEXT N
490 PRINT TAB(71);" "\GOTO 560
500 PRINT"Z,P,W";\INPUT T1,F,P\F=F/100\IF T1<0 THEN 790
510 IF T1= 0 THEN 1010\IF ABS(P) > 180 THEN 810\IF F = O THEN 530
520 IF  F < 0.1 THEN 830\IF F > 1 THEN 830
530 N = 20\IF T1< 400 THEN 540\N = T1/20
540 T1=T1/N\P=P*3.14159/180\S=SIN(P)\C=COS(P)\M2=M0*T1*F/B
550 R3=-0.5*R0*((V0/R)^2)+R*A1*A1\A3=-2*R1*A1/R
560 FOR I = 1 TO N\IF M1=0 THEN 580\M1=M1-M2\IF M1>0 THEN 590
570 F=F*(1+M1/M2)\M2=M1+M2\PRINT"TREIBSTOFFTANK LEER"\M1=0\GOTO 590
580 F=0\M2=0
590 M=M-0.5*M2\R4=R3\R3=-0.5*R0*((V0/R)^2)+R*A1*A1
600 R2=(3*R3-R4)/2+0.00526*F1*F*C/M\A4=A3\A3=-2*R1*A1/R
610 A2=(3*A3-A4)/2+0.00526*F1*F*S/(M*R)\X=R1*T1+0.5*R2*T1*T1
620 R=R+X\H0=H0+X\R1=R1+R2*T1\A=A+A1*T1+0.5*A2*T1*T1\A1=A1+A2*T1
630 M=M-0.5*M2\T=T+T1\IF H0<D9 THEN 640\NEXT I
640 H=H0*Z\H1=R1*Z\D=R0*A*Z\D1=R*A1*Z\T2=M1*B/M0\T2=INT(T2+0.5)
650 IF H1< 0 THEN 660\H1=INT(H1+0.5)\GOTO 670
660 H1=INT(H1-0.5)
670 IF D < 0 THEN 680\D=INT(D+0.5)\GOTO 690
680 D=INT(D-0.5)
690 IF D1 < 0 THEN 700\D1=INT(D1+0.5)\GOTO 710
700 D1=INT(D1-0.5)
710 IF ABS(H)<1 THEN 730\IF H<0 THEN 720\H=INT(H+0.5)\GOTO 730
720 H=INT(H-0.5)
730 T=INT(T+0.5)\PRINT TAB(1);T;TAB(8);H;TAB(18);D;TAB(36);H1;TAB(49);
740 PRINT D1;TAB(62);T2
750 IF H0<D9 THEN 770\IF R0*A>164.47 THEN 970\IF M1>0 THEN 500
760 T1=20\F=0\P=0\GOTO 530
770 IF R1<-8.2196E-04 THEN 910\IF ABS(R*A1)>4.9317E-04 THEN 910
780 IF H0<-D9 THEN 910\IF ABS(D)>10*Z THEN 990\GOTO 870
790 PRINT"MIT DIESER KAPSEL KOENNEN SIE DIE RAUM-ZEIT GESETZE ";
800 PRINT"NICHT UEBERWINDEN!"\GOTO 500
810 PRINT"WENN SIE HERUMSPINNEN WOLLEN,DANN STEIGEN SIE DOCH AUS!!"
820 GOTO 500
830 PRINT"UNMOEGLICHER SCHUBWERT:";\IF F<0 THEN 860
840 IF F < 0.1 THEN 850\PRINT"ZU GROSS!"\GOTO 500
850 PRINT"ZU KLEIN!"\GOTO 500
860 PRINT"NEGATIVER WERT"\GOTO 500
870 PRINT"HIER IST DIE KONTROLLSTATION -- DER ADLER IST SICHER ";
880 PRINT"GELANDET"\PRINT"HERZLICHEN GLUECKWUNSCH -- ES GAB KEINE ";
890 PRINT"BESCHAEDIGUNGEN AN DER KAPSEL"\PRINT"SIE KOENNEN ";
900 PRINT"NUN MIT DEM FORSCHUNGSPROGRAMM BEGINNEN."\GOTO 1020
910 PRINT PNT(7);"************ WRUMMM ************"
920 PRINT"UM SIE TUT ES MIR NUN WIRKLICH LEID:SIE SIND ABGESTUERZT!"
930 PRINT"DADURCH HABEN SIE EBEN EINEN KRATER VON";ABS(H);M$;
940 PRINT" TIEFE VERURSACHT!"\X1=SQR(D1*D1+H1*H1)
950 PRINT"SIE SIND MIT EINER GESCHWINDIGKEIT VON";X1;"M/SEK";
960 PRINT" AUFGESCHLAGEN"\GOTO 1020
970 PRINT"SIE SIND IM ALL VERLOREN GEGANGEN --"
980 PRINT"OHNE HOFFNUNG AUF EINE WIEDERKEHR"\GOTO 1020
990 PRINT"SIE SIND SICHER GELANDET - - -  SIE HABEN ABER DIE ";
1000 PRINT"LANDESTELLE"\PRINT"UM";ABS(D/G5);N$;" VERFEHLT."\GOTO 1020
1010 PRINT"MISSION IST ABGEBROCHEN!"
1020 PRINT"WOLLEN SIE NOCH MAL FLIEGEN(J ODER N)";\INPUT Z$
1030 IF Z$="J" THEN 50\IF Z$="N" THEN 1040\PRINT R$\GOTO 1020
1040 PRINT"SCHADE,DAS MONDLANDEPROGRAMM BEDAUERT ES IMMER ";
1050 PRINT"ERFAHRENE ASTRONAUTEN"\PRINT"ZU VERLIEREN!"
1060 GOTO 1130
1070 PRINT
1080 PRINT"GUT,WOLLEN SIE NUN DIE KOMPLETTE EINFUEHRUNG(1),DIE EIN";
1090 PRINT"GABE ","AUSGABE EINWEISUNGEN(2) ODER NICHTS VON BEIDEM(3)";
1100 INPUT B1
1110 IF B1=1 THEN 120\IF B1=2 THEN 330\IF B1=3 THEN 450
1120 PRINT R$\GOTO 1080
1130 END