Directory of image this file is from
This file as a plain text file

/PALIB SUBROUTINE LIBRARY
XLIST AAAAAA
/F.WESSELY	SEPT.75

IFDEF HRS <	SCALL=IOF
		ORG=4003
		FIXTAB	>	/HRS-CALL DEFINITIONS



FIXMRI CALL=JMS
FIXTAB

IFDEF EEEEEE <
XLIST EEEEEE >

/DEFINITIONS OF SUBROUTINE NAMES
/AND SUBCALL SEQUENCES


IFDEF INXO4 <IFNDEF LISTN <LISTN=0>
             IFDEF OS8 <IFNDEF PRINT <PRINT=0>>
              INXO4X=41 >

IFDEF LISTN <IFDEF OS8 <IFNDEF PRINT <PRINT=0>
		        LISTNX=7>
	     IFDEF HRS <LISTNX=7>>

IFDEF WRITE <IFDEF OS8 <IFNDEF PRINT <PRINT=0>
			    WRITEX=15>
		IFDEF HRS < WRITEX=13>>

/FIELD &PAGE SETTINGS

IFDEF FFFFFF <
XLIST 0
FIELD FFFFFF
XLIST 1 >
IFDEF BBBBBB <
XLIST 0
      *BBBBBB
XLIST 1 >

IFNDEF BBBBBB <BBBBBB=.>
XLIST 0

/ROUTINES ASSEMBLED:
XLIST AAAAAA

IFDEF WRITE <
XXXXXX=BBBBBB&177
IFNZRO 177-WRITEX-XXXXXX&4000 <PAGE>
BBBBBB=.+WRITEX
XLIST 0
WRITE=.
XLIST 1
IFDEF LLLLLL <
XLIST LLLLLL >

/SUBROUTINE WRITE

WRITE, 	HLT
	DCA 	.+7
	TAD I	WRITE
	DCA 	.+6
	ISZ 	WRITE
	SCALL
	ORG
	5
	0
	0
	JMP I	WRITE
XLIST AAAAAA	>

IFDEF INXO4 <
IFDEF EEEEEE <
XLIST EEEEEE >
XXXXXX=BBBBBB&177
IFNZRO 177-INXO4X-XXXXXX&4000 <PAGE>
BBBBBB=.+INXO4X
XLIST 0
INXO4=.
XLIST AAAAAA
IFDEF LLLLLL <
XLIST LLLLLL >
/SUBROUTINE INXO4

/INPUTS AN ABS. INTEGER OF
/BASIS X &TRANSFERS TO BINARY

/CALLING SEQUENCE:
/
/	TAD (-X
/	JMS INXO4	/CALL
/	JMP ERR		/IF NON-NUMERIC CHAR.
/			/OR OVERFLOW
/	.......		/NORMAL RETURN
/			/AC CONTAINS OCT. VALUE

INXO4,	HLT
	DCA	INXO41
	DCA 	INXO42
	CLA CLL

INXO45,	TAD	INXO41
	DCA	INXO43
	CALL	LISTN		/GET A CHARACTER
	TAD	INXO47
	DCA 	INXO44
	TAD	INXO44
	SPA			/DELIMITER?
	JMP	INXO46 		/YES-  RETURN
	TAD	INXO41		/MAY BE- ?
	SMA CLA
	JMP I	INXO4
	CLA CLL
	TAD 	INXO42
	SZL			/OVERFLOW?
	JMP I	INXO4		/YES- ERR RETURN
	ISZ	INXO43		/INXO42*INXO41 DONE ?
	JMP	.-4		/NO-
	TAD	INXO44		/YES- ADD INXO44
	DCA	INXO42		/INXO42 =INXO42*INXO41+INXO44
	JMP	INXO45

INXO46,	CLA CLL			/WE HAVE A INXO46IMITER
	TAD 	INXO42		/LOAD INTEGER &RETURN
	ISZ	INXO4
	JMP I	INXO4


INXO44,	0
INXO42,	0
INXO41,	0
INXO43,	0
INXO47,	-260


XLIST AAAAAA	>


IFDEF LISTN <
IFDEF EEEEEE<
XLIST EEEEEE>
XXXXXX=BBBBBB&177
IFNZRO 177-LISTNX-XXXXXX&4000 <PAGE>
BBBBBB=.+LISTNX
XLIST 0
LISTN=.
XLIST AAAAAA
IFDEF LLLLLL <
XLIST LLLLLL >

/SUBROUTINE LISTN

/CALLING SEQUENCE
/	TAD DEVICE NUMBER (0 OR 1)
/	CALL LISTN
/	......		/AC CONTAINS CHARACTER ON RETURN
XLIST AAAAAA
IFDEF HRS <
IFDEF LLLLLL <
XLIST LLLLLL >
LISTN,	HLT
	DCA	.+4
	SCALL
	ORG
	6
	0
	JMP I	LISTN
XLIST AAAAAA	>

XLIST 0