Directory of image this file is from
This file as a plain text file

/		PROGRAM: PARITY.PA
/
/PAL-8 EVEN-PARITY PUNCHED TAPE GENERATOR
/PROGRAM DESIGNED TO READ A KEYBOARD (READER) INPUT FROM
/KEYBOARD I (IOT 603X) AND PRINT/PUNCH AN EVEN PARITY
/OUTPUT ON PRINTER II (IOT 641X).
/
/
	KCC2=6402
	TSF2=6411
	TLS2=6416
	FIXTAB
	*200
	KCC		/INITIALIZE KEYBOARD1
	KCC2		/INITIALIZE KEYBOARD2
	TLS		/INITIALIZE PRINTER1
	TLS2		/INITIALIZE PRINTER2
BEGIN,	KSF		/WAIT FOR KEYBOARD FLAG
	JMP .-1	
	KRB		/READ IN CHARACTER
	DCA STORE1	/STORE CHARCACTER
	TAD STORE1
	TAD MCTRLC
	SNA		/IS CHARACTER CONTROL-C ??
	JMP I OS8	/YES...RETURN TO OS/8 MONITOR
	CLA
	TAD STORE1
	JMS PARITY	/NO...GENERATE EVEN PARITY
			/FOR THE INPUT CHARACTER
	TSF2		/WAIT FOR PRINTER2 FLAG
	JMP .-1
	TLS2		/PRINT(PUNCH) CHARCTER WITH 
			/EVEN PARITY GENERATED ON KRB2
	JMP BEGIN
STORE1,	0
MCTRLC,	7575
OS8,	7600
/................ EVEN PARITY GENERATION ROUTINE
PARITY,	0		/SUBROUTINE RETURN ADDRESS
	AND MASK	/ZERO BITS 0-3 OF CHAR WORD
	DCA DATA
	TAD M8
	DCA COUNT	/SET COUNTER = MINUS 8
	DCA BITS	/SET BIT COUNT = 0
	TAD DATA
	RAR
	RAR		/LOOP TO ROATATE ALL THE CHARACTER
	SPA		/BITS THROUGH AC(0), CHECKING FOR 
	ISZ BITS	/AND COUNTING BINARY ONES, THE SUM
	ISZ COUNT	/BEING STORED IN "BITS".
	JMP .-4		/
	CLA
	TAD BITS
	RAR
	CLA
	SZL		/IS BIT COUNT EVEN ??
	TAD BIT4	/NO...SET PARITY BIT.
			/YES...
	TAD DATA	/ADD CHARACTER WORD TO PARITY BIT IF PRESENT
	JMP I PARITY	/RETURN TO CALLING PROGRAM
			/WITH EVEN-PARITY CHAR IN AC
DATA,	0
COUNT,	0
BITS,	0
MASK,	0177
M8,	7770
BIT4,	0200
$