File QUICKF.PA (PAL assembler source file)

Directory of image this file is from
This file as a plain text file

/ QUICK LOAD FORMAT FLOPPY BOOT FOR DSD 210-8
/ QUICKF.PA	7/29/76

/ REQUIRES KEYING IN FOLLOWING BOOTSTRAP, THEN PLACING FIRST 
/ CHAR PUNCHED ON TAPE OVER TELETYPE (DEVICE 03) READER PRONGS
/ AND STARTING AT 27.  PRESS CONTINUE TWICE AFTER TAPE STOPS.
/ TAPE WILL STOP AND BOOTSTRAPPING WILL OCCOUR ON DRIVE 0.

	XLIST
PUNCHD,	HLT	/ CONTINUE TO PUNCH TAPE LEADER.
	JMS PUNCHT
LDR,	0; 0; 0; 0; 0; 0; 0; 0
	317; 272; 367; 127; 107; 61	/ FIRST OVERLAY
	040; 317; 102; 367; 067; 067; 067	/ GET HIGH CHAR
	041; 317; 172; 367; 044; 231	/ GET LOW CHAR AND LOAD
	075; 106; 066; 102		/ START NORMAL LOOP
	34; 07	/ RELOAD LOAD COMMAND
	77; 17	/ DISPATCH ADDRESS.
	54; 05	/ DISPATCH COMMAND.
	77; 16	/ LOAD COMMAND.

PUNCHT,	0
	TAD PUNCHK; DCA PUNCNT	/ CHAR COUNTER.
PUNCHL,	TAD I PUNCHT; TLS
	TSF; JMP .-1
	CLA CLL
	ISZ PUNCHT
	ISZ PUNCNT; JMP PUNCHL
	JMP	PUNCHD

PUNCNT,	0
PUNCHK,	LDR-PUNCHT
	XLIST

NOPUNCH
	*27
/ KEY IN FOLLOW ING BOOTSTRAP.
START,	KCC	/ START HERE FROM SWITCHES.
	HLT
	KRB
	RTR
	RAR
	DCA 27
	ISZ .-1
	JMP 30

/ THIS IS OVERLAYED BY THE DATA ON THE TAPE ROTATED 3 RIGHT

	*27
	/MEANING / DATA READ FROM TAPE

	KSF	/ 317
	JMP .-1	/ 272	/ INSTALL WAIT LOOP
	KRB	/ 367
	RTR	/ 127
	RAR	/ 107
	DCA 6	/  61	/ START LOADING AT 7
/	ISZ 34	/ INSTRUCTIONS USED FROM ORIGINAL BOOT.
/	JMP 30
/ USE ABOVE TO LOAD NEXT STAGE.

*6+1
TMP=4	/ USED FOR 6 BIT MERGE.

PTR,	4	/  40	/ VAL = 4 TO START LOAD AT 5
LP,	KSF	/ 317
	JMP .-1	/ 102
	KRB	/ 367
	RTL	/  67
	RTL	/  67
	RTL	/  67
	DCA TMP /  41
	KSF	/ 317
	JMP .-1	/ 172
	KRB	/ 367
	TAD TMP /  44
	DCA .	/ 231	/ OVERLAYED WHEN LOOP STARTED.
	ISZ PTR	/  75
	JMP LP	/ 106
	JMP FIN	/  66	/ EXIT AFTER 7777 LOADED.
	JMP LP	/ 102	/ START THE REGULAR LOAD LOOP.

*23	/ LOADED HERE BECAUSE OF DCA . AT 23
	DCA I PTR / 34, 7	/ ASSEMBLE 2 BYTES NOW.

*5
DISPAT,	STARTB	  / 77, 17	/ USE AS DISPATCH ADDRESS.
FIN,	JMP I .-1 / 54, 05	/ LOAD THE EXIT DISPATCH
	LOADBG	  / 77, 16	/ START LOADING BOOTSTRAP HERE.
ENPUNCH

*7716	/ PUNCH AN ORIGIN
LOADBG,	.

STARTB,	TAD I SRC; DCA I DEST
	ISZ DEST
	ISZ SRC; JMP STARTB
	6007	/ CLEAR ALL FLAGS
	6755; NOP
	6757
	JMP 33
DEST,	33
SRC,	.+1

	6755
	JMP 54
	JMP 45
	HLT
	HLT
	HLT
	 HLT
	HLT
	HLT
	HLT
	CLA STL RTL
	6751
	JMS 53
	DCA 2
	ISZ 50
	JMP 47

	0
	6753
	JMP 33
	6752
	5453
	7004
	0; 0; 0
$	$	$	$	$	$



Feel free to contact me, David Gesswein djg@pdp8online.com with any questions, comments on the web site, or if you have related equipment, documentation, software etc. you are willing to part with.  I am interested in anything PDP-8 related, computers, peripherals used with them, DEC or third party, or documentation. 

PDP-8 Home Page   PDP-8 Site Map   PDP-8 Site Search