10 PRINT TAB(23);"SPIELREGELN:"
20 PRINT
30 PRINT "BEI DIESEM SPIEL SOLLEN SIE ZWEI DURCH * BZW. # DARGESTELLTE"
40 PRINT "AUTOS AUF EINEM ZICK-ZACK-KURS(WENDUNG ALLE 12 ZEILEN)"
50 PRINT "STEUERN (NEG. ZAHL=LINKS, 0=GERADE, POS. ZAHL=RECHTS)."
60 PRINT "ES IST NICHT ERLAUBT ZWEIMAL HINTEREINANDER MIT DER GLEICHEN"
70 PRINT "ZAHL ZU STEUERN! AUSSERDEM BESCHLEUNIGEN DIE AUTOS STETIG"
80 PRINT "DAS HEISST SIE FAHREN NACH JEDER RICHTUNGSAENDERUNG UM EINE"
90 PRINT "ZEILE WEITER ALS VORHER. WER AM LAENGSTEN AUF DER BAHN BLEIBT"
100 PRINT "HAT DAS SPIEL GEWONNEN UND BEKOMMT EINEN PUNKT FUER DIE"
110 PRINT "ABRECHNUNG AM ENDE DER RUNDE. WENN BEIDE AUTOS KOLLIDIEREN"
120 PRINT "IST DIE RUNDE AUTOMATISCH ZU ENDE.UNFAELLE WERDEN"
130 PRINT "DADURCH ANGEZEIGT DASS IRGENDEIN ZEICHEN (AUTO ODER"
140 PRINT "RECHTE STRASSENSEITE) AUF UNERWARTETER POSITION ERSCHEINT."
150 PRINT 
160 PRINT TAB(23);"VIEL SPASS!!"
170 LET Z1=0\Z2=0
180 PRINT\PRINT\PRINT 
190 LET E1=0\E2=0
195 LET X=0
200 PRINT TAB(50);"RICHTUNG:"
210 PRINT TAB(7);"A";TAB(15);"B"
220 PRINT "II";TAB(7);"*";TAB(15);"#";TAB(20);"II"
230 PRINT TAB(3);"II";TAB(7);"*";TAB(15);"#";TAB(22);"II";TAB(51);
240 LET B1=7\B2=15
250 LET D=1
260 LET I=3
270  FOR C=3 TO 35 
280 IF O=1 THEN 330
290 PRINT "A ZUERST";
300 INPUT A1,A2
310 LET O=1
320 GOTO 360
330 PRINT "B ZUERST";
340 INPUT A2,A1
350 LET O=0
360 IF A1=E1 THEN 810
370 IF A2=E2 THEN 840
380 IF A1-E1>6 THEN 1180
390 IF A1-E1<-6 THEN 1180
400 IF A2-E2>6 THEN 1230
410 IF A2-E2<-6 THEN 1230
420 FOR D=1 TO C
430 IF X=2 THEN 470
440 IF X=-2 THEN 490
450 LET X=2
460 GOTO 510
470 IF I=23 THEN 500
480 GOTO 510
490 IF I=1 THEN 450
500 LET X=-2
510 LET I=I+X 
520 LET B1=B1+A1
530 LET B2=B2+A2
540 LET E1=A1
550 LET E2=A2
560 IF D=C THEN 590
570 PRINT TAB(I);"II";TAB(B1);"*";TAB(B2);"#";TAB(19+I);"II"
580 GOTO 600
590 PRINT TAB(I);"II";TAB(B1);"*";TAB(B2);"#";TAB(19+I);"II";TAB(51);
600 IF B1<=I+1 THEN 670
610 IF B1>=I+20 THEN 670
620 IF B2<=I+1 THEN 720
630 IF B2>=I+20 THEN 720
640 IF B1>=B2 THEN 1110
650 NEXT D
660 NEXT C
670 IF B2<=I+1 THEN 1090
680 IF B2>=I+20 THEN 1090
690 PRINT "UNFALL WAGEN A.B IST SIEGER!"
700 LET Z2=Z2+1
710 GOTO 740
720 PRINT "UNFALL WAGEN B.A IST SIEGER!"
730 LET Z1=Z1+1
740 PRINT 
750 PRINT "WOLLEN SIE NOCH EIN SPIEL(JA ODER NEIN)";
760 INPUT Z$
770 IF Z$="JA" THEN 180
780 IF Z$="NEIN" THEN 860
790 PRINT "WAS HABEN SIE GESAGT";
800 GOTO 760
810 IF A2=E2 THEN 1260
820 PRINT TAB(46);"A MOGELT!NOCH EINMAL!";
830 GOTO 1130
840 PRINT TAB(46);"B MOGELT!NOCH EINMAL!";
850 GOTO 1130
860 PRINT 
870 PRINT
880 PRINT "PUNKTEVERTEILUNG:"
890 PRINT 
900 PRINT "I";TAB(5);"A";TAB(10);"I";TAB(15);"B";TAB(20);"I"
910 PRINT "I";TAB(10);"I";TAB(20);"I"
920 PRINT "I";TAB(4);Z1;TAB(10);"I";TAB(14);Z2;TAB(20);"I"
930 PRINT
940 IF Z1>Z2 THEN 970
950 IF Z1<Z2 THEN 990
960 IF Z1=Z2 THEN 1010
970 PRINT "A IST GESAMTSIEGER"
980 GOTO 1020
990 PRINT "B IST GESAMTSIEGER"
1000 GOTO 1020
1010 PRINT "UNENTSCHIEDEN" 
1020 PRINT\PRINT\PRINT
1030 PRINT "WOLLEN SIE NOCH EINE RUNDE(JA ODER NEIN)";
1040 INPUT Z$
1050 IF Z$="JA" THEN170
1060 IF Z$="NEIN" THEN 1300
1070 PRINT "WAS HABEN SIE GESAGT";
1080 GOTO 1040
1090 PRINT "GLEICHZEITIGE UNFAELLE!KEIN PUNKT!"
1100 GOTO 740
1110 PRINT "ZUSAMMENSTOSS!DIE RUNDE IST ZU ENDE!"
1120 GOTO 860
1130 IF O=1 THEN 1160
1140 INPUT A2,A1
1150 GOTO 360
1160 INPUT A1,A2
1170 GOTO 360
1180 IF A2-E2>6 THEN 1280
1190 IF A2-E2<-6 THEN 1280
1200 PRINT "SPIELER A HAT ZU SCHARF GELENKT.SEIN WAGEN IST"
1210 PRINT "DESHALB INS SCHLEUDERN GERATEN.B IST SIEGER!"
1220 GOTO 700
1230 PRINT "SPIELER B HAT ZU SCHARF GELENKT.SEIN WAGEN IST"
1240 PRINT "DESHALB INS SCHLEUDERN GERATEN.A IST SIEGER!"
1250 GOTO 730
1260 PRINT TAB(46);"BEIDE MOGELN!";
1270 GOTO 1130
1280 PRINT "BEIDE HABEN ZU SCHARF GELENKT!KEIN PUNKT!"
1290 GOTO 740
1300 END