Directory of image this file is from
This file as a plain text file

/RETTER
/MIT DIESEM PROGRAMM KOENNEN SIE DATEN VON EINEM BAND
/RETTEN, DESSEN DIRECTORY NICHT EINWANDFREI IST.
/DIE STEUERANGABEN ERFOLGEN UEBER DEN COMMAND-DECODER
/IN FOLGENDER REIHENFOLGE:
/OUTPUT-GERAET:
/OUTPUT-FILE.EXTENSION
/[ANZAHL DER ZU UEBERTRAGENDEN BLOECKE (DEZIMAL)]
/<
/INPUT-GERAET:
/=STARTBLOCKNUMMER (OKTAL)
/DIE BLOCKZAHL DARF NICHT GROESSER ALS 32 (DEZIMAL)
/SEIN




*200
	CIF 10
	CDF 10
	JMP 2000	/SPRUNG IN FELD 1
FIELD 1
*2000
	JMS I (7700	/USRIN
	10
	CLA
	JMS I (200	/COMMAND-DECODER
	5
	0
	0
	CLA		/FETCH LESEHDLR.
	TAD 7617	/MIT
	AND (17		/DEVICENUMMER
	DCA LGNR	/LESEGERAETNUMMER
	TAD LGNR
	JMS I (200
	1
ENTRL,	2001		/LESEHNDLR AUF PAGE 10
	JMP ER1
	CLA		/FETCH SCHREIBHDLR.
	TAD 7600	/MIT DEVICENUMMER
	AND (17
	DCA SGNR	/SCHREIBGERAETNUMMER
	TAD SGNR
	JMS I (200
	1
ENTRS,	2401		/SCHREIBHDLR. AUF PAGE 12
	JMP ER2
	CLA
	TAD 7600	/ENTER MIT FILELAENGE
	JMS I (200
	3
STAR1,	7601
	0
	JMP ER3
	CLA CLL
	TAD STAR1	/STARTBLOCKNUMMER SICHERN
	DCA STAR2
	TAD 7600	/BLOCKZAHL AUFBEREITEN
	AND (7760	/MEHR ALS 32 BLOCKS?
	RTR;RTR
	DCA BLZ
	TAD (40
	CIA
	TAD BLZ
	SMA SZA		/AC <=0 ?
	JMP ERR
	CLA CLL
	TAD BLZ
	RTL;RTL;RTL
	TAD (4030	/SCHREIBEN VON F 3,BANDL. RUECKW.
	DCA SCWRD
	TAD SCWRD
	TAD (-4000	/LESEN AUF F3, BANDL. RUECKW.
	DCA LCWRD
	TAD 7646	/VOM COMMAMD DECODER
	DCA STAR4	/LESESTARTBLOCKNUMMER
	CIF 0		/LESEHDLR. AUFRUFEN
	JMS I ENTRL
LCWRD,	0
	0
STAR4,	0
	JMP ER4
	CIF 0		/SCHREIBHDLR. AUFRUFEN
	JMS I ENTRS
SCWRD,	0
	0
STAR2,	0
	JMP ER5
	CLA CLL
	TAD SGNR	/CLOSE
	CIF 10
	CDF 10
	JMS I (200
	4
	7601
BLZ,	0
	JMP ER6
OUT,	JMS I (200
	11
	CDF 0
	CIF 0
	JMP 7600
ERR,	JMS I (200	/KEIN PLATZ
	7
	11
ER1,	JMS I (200	/FEHLER FETCH LESEHDLR.
	7
	1
ER2,	JMS I (200	/FEHLER FETCH SCHREIBHDLR.
	7
	2
ER3,	JMS I (200	/FEHLER ENTER OUT-PUT-FILE
	7
	3
ER4,	JMS I (200	/FEHLER BEIM LESEN
	7
	4
ER5,	JMS I (200	/FEHLER BEIM SCHREIBEN
	7
	5
ER6,	JMS I (200	/FEHLER BEI CLOSE
	7
	6
SGNR,	0
LGNR,	0
	$