10 DIM T$(24,12),D$(24,20),H$(70),B$(20),B$(24,20),K$(70),J$(2)
20 T$(1)="NA"\T$(2)="VO"\T$(3)="GESCHL"
30 T$(4)="PLZ&WO"\T$(5)="STR&HNR"\T$(6)="TEL"
40 T$(7)="GEBDAT"\T$(8)="GEBORT"\T$(9)="KONF"
50 T$(10)="ERZBER VANA"\T$(11)="         VO"
60 T$(13)="       MUNA"
70 T$(12)="        BER"\T$(16)="EB.AD.PLZ&WO"
80 T$(17)="     STR&HNR"\T$(14)=T$(11)\T$(15)=T$(12)
90 T$(18)="KIZ"\T$(19)="GEBJ"\T$(20)="BEHIND"
100 T$(21)="FAHRK"\T$(22)="VON SCHULE"
110 T$(23)="SCHULJ BISH"\T$(24)="BEMKG"
120 PRINT "DATUM"\H$="0000"\INPUTH$\J$=SEG$(H$,5,6)\H$=SEG$(H$,1,4)
130 PRINT"VORM. ODER NACHM.";
140 INPUT K$\K$=SEG$(K$,1,2)
150 PRINT"BENUTZER",\INPUT B$
160 B=24\S$="***"\Z=0
170 K$="AN:"&H$&K$&".BA"
180 FILEV#1:K$
190 PRINT"DIE DATEN WERDEN AUF FILE ";SEG$(K$,4,9);" GESPEICHERT"
200 PRINT\PRINT\PRINT
210 PRINT#1:B$\PRINT#1:STR$(B)\PRINT#1:S$&S$&S$
220 A=1\FOR I=1 TO 24\D$(I)="0000"\NEXT I
230 Z=Z+1
240 FOR I=A TO B
250 PRINTT$(I);\INPUT H$\IF H$="000"THEN 340
260 GOSUB 530
265 IF W1=1 THEN 250
267 IF W2=1 THEN 240
270 D$(I)=H$
280 NEXT I
290 FOR I= 1 TO 24
300 PRINT#1:D$(I)
310 NEXT I
320 PRINT\PRINT\PRINT\PRINT\PRINT
330 GOTO 220
340 PRINT#1:S$&S$&S$&S$\PRINT#1:STR$(Z-1)\CLOSE#1
350 PRINTZ-1;"DATENSAETZE WURDEN AUF FILE ";SEG$(K$,4,9);
360 PRINT" GESPEICHERT"
370 PRINT\PRINT\PRINT\PRINT\PRINT
380 PRINT"FOLGENDE SCHUELER WURDEN AM ";
390 PRINT SEG$(K$,4,5);".";SEG$(K$,6,7);".19";J$;" ";SEG$(K$,8,9)
400 PRINT"BEI ";B$;" ANGEMELDET"
410 PRINT
420FILE#1:K$\INPUT#1:B$,B$,B$
430 FOR I=1 TO Z-1
440 FOR K=1 TO 4\INPUT#1:B$(K)\NEXT K
450 PRINT B$(1);TAB(22);B$(2);TAB(44);B$(4)
460 FOR J=1 TO 20\INPUT#1:H$\NEXT J
470 IF I/30-INT(I/30)<>0 THEN 490
480 GOSUB 600
490 NEXT I
500 PRINT\PRINT "ENDE"
510 CLOSE #1
520 STOP
530 REM SUBR.PRUEF
535 W1=0\W2=0
540 IF LEN(H$)<=20 THEN 560
550 PRINT"MEHR ALS 20 ZEICHEN,ERBITTE KUERZERE EINGABE"\W1=1\GOTO590
560 IF H$<>"^" THEN 580
570 A=I-1\W2=1\IF A>0THEN590\A=1\GOTO590
580 IF H$<>SEG$(H$,1,-1)THEN590\H$="0"\GOTO590
590 RETURN
600 FOR L=1 TO 17\PRINT\NEXT L
610 FOR L=1 TO 20\PRINT"-";\NEXT L\PRINT\PRINT\PRINT\PRINT
620 RETURN
630 END