File SMOOTH.PA (PAL assembler source file)

Directory of image this file is from
This file as a plain text file

/SMOOTHING ROUTINE FOR PATTERN RECOGNITION/
/****SIMON C STEELY*AND*ERIC ENGQUIST*****/
FIELD 2
*0020
MQA=7501
SWP=7521
WADDR,0
PPOINT,0
IMPNGB,0
TRVNGB,0
LTCH,0
BTABLE,0
WTABLE,0
WL,-14
WCHK,-14
LCNT,0
MCNT,0
*0200
SMOOTH,0
 CLL STL RAR
 DCA PPOINT
 TAD WL
 DCA WCHK
 TAD (600)
 DCA WTABLE
 TAD (1000)
 DCA BTABLE
 TAD (-40)
 DCA MCNT
 TAD (-40)
 DCA LCNT
COUNT, DCA IMPNGB
 DCA TRVNGB
 JMS INCW
 JMS LIT
 ISZ LTCH
 JMP C1
 ISZ  IMPNGB
C1, JMS DECW
 JMS LIT
 ISZ LTCH
 JMP C2
 ISZ IMPNGB
C2, JMS INCW
 JMS SPOT
 JMS LIT
 ISZ LTCH
 JMP C3
 ISZ IMPNGB
C3, JMS INCW
 JMS LIT
 ISZ LTCH
 JMP C4
 ISZ TRVNGB
C4, JMS DECW
 JMS LIT
 ISZ LTCH
 JMP C5
 ISZ TRVNGB
C5, JMS INCW
 JMS RESPOT
 JMS RESPOT
 JMS LIT
 ISZ LTCH
 JMP C6
 ISZ IMPNGB
C6, JMS INCW
 JMS LIT
 ISZ LTCH
 JMP C7
 ISZ TRVNGB
C7, JMS DECW
 JMS LIT 
 ISZ LTCH
 JMP C8
 ISZ TRVNGB
C8, JMS INCW
 JMS SPOT
 TAD IMPNGB
 TAD (JMP KEY+1)
 DCA .+1
KEY, JMP KEY+1
AZER0, JMP XBLK
ZERO, JMP ONECHK
ZERO2, JMP TWOCHK
XWHITE, JMP XWHIT
 JMP  XWHIT
XWHIT, JMS LIT
 ISZ LTCH
 JMP WCHNGE
 JMP INCRMT
XBLK, JMS LIT
 ISZ LTCH
 JMP BCHNGE
 JMP INCRMT
ONECHK, TAD TRVNGB
 TAD (-3)
 SPA CLA
 JMP XBLK
 JMP XWHIT
TWOCHK, STA
 TAD TRVNGB
 SPA SNA
 JMP XBLK
 TAD (-2)
 SPA CLA
 JMP INCRMT
 JMP XWHIT
INCRMT, JMS SPOT
 ISZ LCNT
 JMP COUNT
 TAD WL
 DCA WCHK
 TAD (4000)
 DCA PPOINT
 TAD WADDR
 TAD (16)
 DCA WADDR
 ISZ MCNT
 JMP COUNT-2
 JMP WHIMPL
*0400
WHIMPL, TAD (577)
 DCA 12
 TAD I 12
 DCA WADDR
 TAD I 12
 DCA PPOINT
 TAD PPOINT
 SWP 
 CLA CLL
 TAD I WADDR
 MQA
 DCA I WADDR
 TAD 12
 CIA
 TAD WTABLE
 SMA SZA CLA
 JMP WHIMPL+2
BLIMPL, TAD (777)
 DCA 12
 TAD I 12
 DCA WADDR
 TAD I 12
 CIA
 DCA PPOINT
 TAD PPOINT
 SWP 
 CLA CLL
 TAD I WADDR
 MQA
 DCA I WADDR
 TAD 12
 CIA
 TAD BTABLE
 SMA SZA CLA
 JMP BLIMPL+2
 HLT
LIT, 0
 TAD I WADDR
 AND I PPOINT
 SNA CLA
 JMP I LIT
 STA
 DCA LTCH
 JMP I LIT
INCW, 0
 TAD WADDR
 TAD  (20)
 DCA WADDR
 JMP I INCW
DECW,0
 TAD WADDR
 TAD (-40)
 DCA WADDR
 JMP I DECW
SPOT, 0
 ISZ WCHK
 JMP .+7
 TAD WL
 DCA WCHK
 TAD (4000)
 DCA PPOINT
 ISZ WADDR
 JMP I SPOT
 TAD PPOINT
 RAR
 DCA PPOINT
 JMP I SPOT
RESPOT,0
 STA
 TAD WCHK
 DCA WCHK
 TAD (15)
 TAD WCHK
 SZA CLA
 JMP .+11
 STA
 DCA WCHK
 IAC 
 DCA PPOINT
 STA
 TAD WADDR
 DCA WADDR
 JMP I RESPOT
 TAD PPOINT
 RAL
 DCA PPOINT
JMP I RESPOT
WCHNGE, TAD WADDR
 DCA I WTABLE
 ISZ WTABLE
 TAD PPOINT
 DCA I WTABLE
 ISZ WTABLE
 JMP INCRMT
BCHNGE, TAD WADDR
 DCA I BTABLE
 ISZ BTABLE
 TAD PPOINT
 DCA I BTABLE 
 ISZ BTABLE
 JMP INCRMT
$

Feel free to contact me, David Gesswein djg@pdp8online.com with any questions, comments on the web site, or if you have related equipment, documentation, software etc. you are willing to part with. I am interested in anything PDP-8 related, computers, peripherals used with them, DEC or third party, or documentation.

PDP-8 Home Page PDP-8 Site Map PDP-8 Site Search