Directory of image this file is from
This file as a plain text file

//	VT52 SUBROUTINES.
/
/	JVE  07MAR76
/
/	THE VT52 IS ASSUMED TO BE UNIT 1, AND ALL OUTPUT TO
/	THE VT52 IS DONE VIA GENIO TO UNIT 1.
/
/	CALL VTHOM - SEND CURSOR TO UPPER LEFT HAND CORNER.
/
/	CALL VTCLR - CLEAR TO END OF VT52 SCREEN
/
/	CALL VTESC(ICODE) - SENDS ESCAPE,ICODE TO VT52.
/
/	CALL VTPOS(IX,IY) - POSITIONS VT52 CURSOR AT
/			    COLUMN IX IN ROW IY.
/			    (ROW 1 IS AT BOTTOM OF SCREEN)
/			    (COLUMN 1 IS AT LEFT EDGE OF SCREEN)
/
//

/-------------------------------------------------------

	ENTRY VTHOM
	ENTRY VTCLR
	ENTRY VTESC
	ENTRY VTPOS

	OPDEF	TADI	1400

/-------------------------------------------------------

VTCLR,	BLOCK 2		/	CALL VTCLR - (ESC J)
	TAD ("J
	JMS ESC
	RETRN VTCLR

VTHOM,	BLOCK 2		/	CALL VTHOM - (ESC H)
	TAD ("H
	JMS ESC
	RETRN VTHOM

POST,
VTESC,	BLOCK 2		/	CALL VTESC(ICODE) - (ESC ICODE)
	TAD VTESC
	DCA VTESC1
VTESC1,	HLT
	TADI VTESC#
	DCA VTESC2
	INC VTESC#
	TADI VTESC#
	DCA VTESC1
	INC VTESC#
VTESC2,	HLT
	TADI VTESC1
	JMS ESC
	RETRN VTESC

VTPOS,	BLOCK 2		/	CALL VTPOS(IX,IY) - (ESC Y 70-IY 37+IX)
	TAD ("Y
	JMS ESC
	JMS PPOS
	DCA POST
	JMS PPOS
	CIA
	TAD (70
	JMS SEND1
	TAD POST
	TAD (37
	JMS SEND1
	RETRN VTPOS

PPOS,	0		/GET PARAMETER FOR VTPOS.
	TAD VTPOS
	DCA PPOS1
PPOS1,	HLT
	TADI VTPOS#
	DCA PPOS2
	INC VTPOS#
	TADI VTPOS#
	DCA PPOS1
	INC VTPOS#
PPOS2,	HLT
	TADI PPOS1
	JMP I PPOS

ESCT,	0
ESC,	0		/SEND CODE IN AC AFTER SENDING ESCAPE.
	DCA ESCT
	TAD (033
	JMS SEND1
	TAD ESCT
	JMS SEND1
	JMP I ESC

SEND1,	0		/SEND 1 CHAR TO VT52.
	CALL 0,GENIO
	JMP I SEND1

	END