5 PRINT "DATENSATZNAME (MAXIMAL 6 ZEICHEN !!!)";\INPUT Y$
10 DIM N$(20),X$(15)\X$="DTA1:"&Y$&".BA"
15 FILEV#1:X$
20 REM EINGABE DER LEISTUNGSKURSERGEBNISSE 12.1 - 13.1, BERECHNUNG
30 REM DER AUSGLEICHSREGELUNG, PRUEFUNG DER ZULASSUNGSBEDINGUNGEN
40 REM AUSGABE BEI TTY UND ABSPEICHERN DER ERGEBNISSE AUF BAND 1
50 REM (ZA1DAL)
60 REM 
80 PRINT"SIND INFORMATIONEN ERWUENSCHT (JA ODER NEIN)";\INPUT A$
90 IF A$ = "NEIN" THEN 230
100 PRINT " AUF ABFRAGE 'NAME' EINGABE DES SCHUELERNAMENS"
110 PRINT "AUF ABFRAGE '1. FACH?' EINGABE DES FAECHERNAMENS EIN-"
120 PRINT "SCHLIESSLICH KURSNUMMER, Z.B.  E5   ODER  PH5  ,"
130 PRINT"DANN RETURN-TASTE. NACH ABFRAGE 'PKTE?' EINGABE DER"
140 PRINT"PUNKTZAHLEN DREIFACHER WERTUNG IN DER REIHENFOLGE:"
150 PRINT"12.1, 12.2, 13.1. "
160 PRINT"DIE EINZELNEN ZAHLEN SIND DURCH KOMMAS ZU TRENNEN. UN-"
170 PRINT"MITTELBAR NACH DER LETZTEN ZAHL DIE RICHTIGKEIT DER"
180 PRINT"EINGABEN PRUEFEN  UND ERST DANACH RETURN-TASTE DRUECKEN."
185 PRINT"NACH ABFRAGE '2. FACH?' ENTSPRECHEND."
190 PRINT"WENN ALLE DATEN ALLER SCHUELER EINGEGEBEN SIND, AUF AB-"
200 PRINT"FRAGE 'NAME?' EINGEBEN:   ENDE   ."
210 Z1=0\Z2=0\Z3=0\Z4=0\Z5=0\Z6=0\Z7=0\Z8=0\Z9=0\Z0=0
230 FOR I = 1 TO 5 \ PRINT\NEXT I
240 PRINT"NAME";\INPUT N$\S=0\D=0\Z$="J"
241IF N$="ENDE" THEN 500
250 FOR I = 1 TO 2\PRINT I;". FACH";\INPUT F$(I)\S(I)=0
260 PRINT, "PKTE";
270 FOR J = 1 TO 3\ INPUT F(I,J)\S(I)=S(I)+F(I,J)\ NEXT J
280 PRINT ,,,F$(I);":";S(I);" PKTE"\ S = S + S(I)\ NEXT I
290 PRINT , "SUMME L-KURSE:",,S; " PKTE"
300 IF F(1,3)>F(2,3) THEN 310\LET A=2*F(2,3)/3\GOTO 320
310 LET A = 2*F(1,3)/3
320 REM
321 REM BERECHNUNG UND AUSGABE
322 REM
330 S = S + A
340 PRINT,"AUSGLEICHSPUNKTE:",A
350 PRINT "PKT-SUMME  LEISTUNGSKURSBEREICH:",S
360 REM
370 REM  PRUEFUNG DER ZULASSUNGSBEDINGUNG
380FOR I = 1 TO 2
390 FOR J = 1 TO 3
400 IF F(I,J) >14 THEN410\ D = D+1
410 NEXT J
420 NEXT I
430 IF D < 3 THEN 450
440 PRINT"NICHT ZUZULASSEN, WEIL MEHR ALS 2 L-KURSE MIT WENIGER"
441 PRINT"ALS 5 PKTEN EINFACHER WERTUNG."\Z$="N"
450 IF S>99 THEN 480
460 PRINT"NICHT ZUZULASSEN, WEIL WENIGER ALS 100 PKTE IM"
470 PRINT"LEISTUNGSKURSBEREICH."\Z$="N"
480 IF Z$="N" THEN 230
485 GOSUB 1000
490 PRINT#1:N$
491 PRINT#1:F$(1)
492 PRINT#1:F$(2)
495 PRINT#1:S(1),S(2)
496 GOTO 230
500 PRINT#1:N$
501 PRINT#1:"O"
502 PRINT#1:"O"
505 PRINT#1:0,0
506 CLOSE#1
510 PRINT"AUF DTA1 BEFINDEN SICH FUER JEDEN SCHUELER, DER IM"
520 PRINT"L-BEREICH DIE ZULASSUNGSBEDINGUNGEN ERREICHT HAT,"
530PRINT"FOLGENDE DATEN:"
531 PRINT"NAME, 1. L-FACH, PKT-SUMME DARIN, 2. L-FACH, PKT-SUMME DARIN"
532 PRINT"JEWEILS DREIFACH."
533 PRINT" DIE E R R E C H N E T E N  DATEN, D.H. PUNKT-SUMMEN"
534 PRINT"AUSGLEICHSPUNKTE UND PUNKTSUMME IM L-BEREICH SIND NOCH"
535 PRINT"IN DIE SCHUELERSTAMMBLAETTER EINZUTRAGEN."
536 PRINT
540 PRINT, "U E B E R S I C H T"
541 PRINT"UEBER DIE GRUPPIERUNG DER ZUGELASSENEN SCHUELER"
542 PRINT"IM L-BEREICH FUER DIE MEDLUNG NACH PARA 18 AB-PO."
543 PRINT
550 PRINT"PKT-ZAHL","ZAHL DER SCHUELER"
551 PRINT"300-276",Z1
552 PRINT"275-251",Z2
553 PRINT"250-231",Z3
554 PRINT"230-211",Z4
555 PRINT"210-191",Z5
556 PRINT"190=171",Z6
557 PRINT"170-151",Z7
558 PRINT"150-131",Z8
559 PRINT"130-116",Z9
560 PRINT"115-100",Z0
570 STOP
997 REM 
998 REM UNTERPROGRAMM  Z A E H L U N G FUER DIE GRUPPIERUNG DER
999 REM ZUGELASSENEN SCHUELER.
1000 IF S<276 THEN 1010\Z1=Z1+1\GOTO 1100
1010 IF S<251 THEN 1020\Z2=Z2+1\GOTO 1100
1020 IF S<231 THEN 1030\Z3=Z3+1\GOTO 1100
1030 IF S<211 THEN 1040\Z4=Z4+1\GOTO 1100
1040 IF S<191 THEN 1050\Z5=Z5+1\GOTO 1100
1050 IF S<171 THEN 1060\Z6=Z6+1\GOTO 1100
1060 IFS<151 THEN 1070\Z7=Z7+1\GOTO 1100
1070 IF S<131 THEN 1080\Z8=Z8+1\GOTO 1100
1080 IF S<116 THEN 1090\Z9=Z9+1\GOTO 1100
1090 Z0=Z0+1
1100 RETURN
2000 END