10 REM AUSLISTUNG DER SCHUELERNAMEN FUER DIE MUENDL. ABIPRUEFUNG
20 REM KURSWEISE.- - - - AUF ABFRAGE 'KURS?' DEN NAMEN DES
30 REM KURSES EINGEBEN.
40 DIMN$(20),F$(6,5),X$(14)
50 PRINT "ABZURUFENDER DATENSATZ";\ INPUT X$
60 X$ = "DTA1:"&X$&".BA"
70 FILE#1: X$
80 Y = 0
90  FOR I = 1 TO 3\ PRINT\ NEXT I
100 Z = 0
110 PRINT, "KURS";\INPUT K$
120 IF K$="ENDE" THEN 360
130 IF K$ ="BESTA" THEN 145\IF K$="NICHT"THEN 145
140 PRINT "ABWEICHUNG",,"GEFAEHRDUNG"
145 GOSUB385
150 INPUT#1: N$,X
160 FOR I = 1 TO 6\ INPUT#1:F$(I),X\NEXT I
170 IF N$ = "ENDE" THEN 330
180 FOR I = 1 TO 3
190  IF K$ <> F$(I) THEN 240
200 PRINT N$
210 IF K$ = "BESTA" THEN 230\ IF K$ = "NICHT" THEN 230
220 Y = Y+1
230 Z = Z + 1
240 NEXT I
250 FOR I = 4 TO 6
260 IF K$ <> F$(I) THEN 310
270 PRINT ,,N$
280 Z = Z + 1
290 IF K$="BESTA" THEN 310\ IF K$ = "NICHT" THEN 310
300 Y = Y+1
310 NEXT I
320 GOTO 150
330 RESTORE#1
335 GOSUB385
336 PRINT
340 PRINT\PRINT Z;" SCHUELER"
350 GOTO 90
360 FOR I = 1 TO 7
370 PRINT\NEXT I
380 PRINT TAB(3);"INSGESAMT ";Y;" PRUEFUNGEN."
381 STOP
385 FOR I = 1 TO 25\PRINT TAB(2*I-1);"-";\NEXT I
386 PRINT
387 RETURN
390 END